EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"
OPEN "","DETAILCALCUL" TO F.DETAILCALCUL ELSE STOP
OPEN "","CONTRAT" TO F.CONTRAT ELSE STOP
OPEN "","CIVILAIDANT" TO F.CIVILAIDANT ELSE STOP
OPEN "","SECTEUR" TO F.SECTEUR ELSE STOP

PRINT "Code du secteur :"
INPUT W_Secteur

PRINT "Annee-Mois de dbut (AAAAMM) :"
INPUT W_Deb

PRINT "Annee-Mois de fin (AAAAMM) :"
INPUT W_Fin

W_TabMois=""
W_SecteurAv=""
W_CleAnc = ""
W_First = "VRAI"
W_Moy=""
W_MoyContratMois=""
W_NbMois=0
W_DiffTotal=0

W_TabMoisTotal=""
W_MoyMoisTotal=0
W_MoyHebdoTotal=0
W_MoyContratMoisTotal=0
W_MoyContratHebdoTotal=0

W_Nombre=0

EXECUTE 'SELECT DETAILCALCUL AVEC SecteurAidantDetailCalcul = "':W_Secteur:'" AND AVEC @ID >= "[':W_Deb:'" AND AVEC @ID <= "[':W_Fin:'" AND AVEC ConvColContratDetailCalcul # "02" AND AVEC TypeContrat # "D" PAR NomPrenomAidantDetailCalcul PAR @ID' 

PRINTER ON

READ ENR_SECTEUR FROM F.SECTEUR,W_Secteur ELSE PRINT "SECTEUR"
PRINT "SECTEUR : ":ENR_SECTEUR<1>
PRINT ""

PRINT "NOM-PRENOM          ":

FOR i = W_Deb TO W_Fin
   IF i[5,2] = 13 THEN
      i=i[1,4] + 1 :"01"
   END
   PRINT "  ":i[5,2]:"   ":
NEXT i

PRINT "MOYB.M MOY.H MOYC.M MOY.H DIFF."
PRINT ""

W_Fini="FAUX"
LOOP
   READNEXT W_Cle ELSE W_Fini="VRAI"
WHILE W_Fini="FAUX" DO
   READ ENR_DETAILCALCUL FROM F.DETAILCALCUL,W_Cle ELSE PRINT "DETAILCALCUL"
   READ ENR_CONTRAT FROM F.CONTRAT,W_Cle[1,8] ELSE PRINT "CONTRAT"

   IF W_CleAnc[1,5] # W_Cle[1,5] AND W_First = "FAUX" THEN

	GOSUB 100

      W_Moy=0
      W_MoyMois=0
      W_MoyHebdo=0
      W_MoyContratMois=0
      W_MoyContratHebdo=0

      W_Diff=0
      W_TabMois=""
      W_NbMois=0
   END

   W_NbMois=W_NbMois+1

   W_TabDeb=W_Deb[5,2]
   IF W_Cle[13,2] => W_TabDeb THEN
      iTab=W_Cle[13,2] - W_TabDeb + 1
   END ELSE
      iTab=12 + W_Cle[13,2] - W_TabDeb + 1

   END

   W_TabMois<iTab>=ENR_DETAILCALCUL<6>

   W_TabMoisTotal<iTab>=W_TabMoisTotal<iTab> + ENR_DETAILCALCUL<6>

   W_Moy=W_Moy + ENR_DETAILCALCUL<6>

   IF ENR_CONTRAT<25,1> = 1 THEN
      W_DureeMois=ENR_CONTRAT<24,1> * 52 / 12
   END ELSE
      IF ENR_CONTRAT<25,1> = 2 THEN
         W_DureeMois=ENR_CONTRAT<24,1> * 26 / 12
      END ELSE
         IF ENR_CONTRAT<25,1> = 3 THEN
            W_DureeMois=ENR_CONTRAT<24,1>
         END ELSE
            W_DureeMois=ENR_CONTRAT<24,1> /12 
         END
      END      
   END

   W_MoyContratMois=W_MoyContratMois + W_DureeMois

   W_CleAnc=W_Cle
   W_First = "FAUX"

REPEAT

GOSUB 100

PRINT ""
ip=1
FOR i = W_Deb TO W_Fin
   IF i[5,2] = 13 THEN
      i=i[1,4] + 1 :"01"
   END
   W_Format=W_TabMoisTotal<ip>
   W_Format=W_Format "R26(#8)"
   PRINT "Mois  ":i[5,2]:": ":W_Format
   ip=ip + 1
NEXT i

W_MoyMoisTotal = W_MoyMoisTotal / W_Nombre
W_MoyHebdoTotal = W_MoyHebdoTotal / W_Nombre
W_MoyContratMoisTotal = W_MoyContratMoisTotal / W_Nombre
W_MoyContratHebdoTotal = W_MoyContratHebdoTotal / W_Nombre
PRINT ""
PRINT "Moyenne totale des heures brutes mensuelles     : ":W_MoyMoisTotal "R26(#8)"
PRINT "Moyenne totale des heures brutes hebdomadaires  : ":W_MoyHebdoTotal "R26(#8)"
PRINT "Moyenne totale des heures mensuelles du contrat : ":W_MoyContratMoisTotal "R26(#8)"
PRINT "Moyenne totale des heures hebdo du contrat      : ":W_MoyContratHebdoTotal "R26(#8)"
PRINT ""

STOP

**********************************************************************************
100
      W_Nombre = W_Nombre + 1

      READ ENR_CIVILAIDANT FROM F.CIVILAIDANT,W_CleAnc[1,5] ELSE PRINT "CIVILAIDANT"

      W_MoyMois=INT(W_Moy / W_NbMois * 100 + 1/2) / 100
      W_MoyMoisTotal=W_MoyMoisTotal + W_MoyMois

      W_MoyContratMois=INT(W_MoyContratMois / W_NbMois + 1/2)
      W_MoyContratMoisTotal=W_MoyContratMoisTotal + W_MoyContratMois

      W_Diff=W_MoyMois - W_MoyContratMois
      W_DiffTotal=W_DiffTotal + W_Diff

      W_MoyHebdo=INT(W_MoyMois * 12 / 52 + 1/2 )
      W_MoyHebdoTotal=W_MoyHebdoTotal + W_MoyHebdo

      W_MoyHebdo=W_MoyHebdo "R26(#5)"
      W_MoyMois=W_MoyMois "R26(#6)"

      W_MoyContratHebdo = INT(W_MoyContratMois * 12 / 52 + 1/2)
      W_MoyContratHebdoTotal=W_MoyContratHebdoTotal + W_MoyContratHebdo

      W_MoyContratHebdo=W_MoyContratHebdo "R26(#5)"
      W_MoyContratMois=W_MoyContratMois "R26(#6)"

      W_Diff=W_Diff "R26(#6)"

      W_NomPrenom=ENR_CIVILAIDANT<2>:" ":ENR_CIVILAIDANT<3>
      W_NomPrenom=W_NomPrenom "L#19"
      W_NomPrenom=W_NomPrenom[1,19]
*      W_CleAnc[1,5]:"  ":
      PRINT W_NomPrenom:
      FOR ip =1 TO 12
         W_Format=W_TabMois<ip>
         W_Format=W_Format "R26(#6)"
         PRINT W_Format:" ":
      NEXT ip
      PRINT W_MoyMois:" ":W_MoyHebdo:" ":W_MoyContratMois:" ":W_MoyContratHebdo:" ":W_Diff


RETURN
