*************************************************
* MOULINETTE DE PASSAGE DES DONNEES DE CONTRAT  *
* EN EUROS                                      *
*                                               *
* JUIN 2001                     STEPHANE HERVET *
*************************************************

EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"
OPEN "","CONTRAT" TO F.CONTRAT ELSE STOP
OPEN "","PERIODESPAIE" TO F.PERIODESPAIE ELSE STOP

READ ENR_PERIODESPAIE FROM F.PERIODESPAIE,"1" ELSE ENR_PERIODESPAIE=""

W_DATEFIN="01/":ENR_PERIODESPAIE<1>[5,2]:"/":ENR_PERIODESPAIE<1>[1,4]
W_DATEFIN=ICONV(W_DATEFIN,"D4/")

EXECUTE 'SSELECT CONTRAT AVEC 65 <> "O" AND AVEC 8 = "" OR >= "':W_DATEFIN:'"'

W_EURO="6.55957"

W_FIN=0
LOOP
     READNEXT CLE ELSE W_FIN=1
     UNTIL W_FIN=1 DO

     READ ENR_CONTRAT FROM F.CONTRAT,CLE ELSE ENR_CONTRAT=""

     IF ENR_CONTRAT<23>="" THEN ENR_CONTRAT<23>=0
     IF ENR_CONTRAT<43>="" THEN ENR_CONTRAT<43>=0
     IF ENR_CONTRAT<46>="" THEN ENR_CONTRAT<46>=0
     IF ENR_CONTRAT<85>="" THEN ENR_CONTRAT<85>=0
     IF ENR_CONTRAT<86>="" THEN ENR_CONTRAT<86>=0

     I=1
     LOOP
	    UNTIL ENR_CONTRAT<23,I>="" DO	
	    ENR_CONTRAT<23,I>=INT((ENR_CONTRAT<23,I>/W_EURO)+1/2)
	    I=I+1
     REPEAT

     IF ENR_CONTRAT<32> # "" THEN         
        ENR_CONTRAT<32>=INT((ENR_CONTRAT<32>/W_EURO)+1/2)     
     END
     IF ENR_CONTRAT<33> # "" THEN    
        ENR_CONTRAT<33>=INT((ENR_CONTRAT<33>/W_EURO)+1/2)     
     END
     ENR_CONTRAT<43>=INT((ENR_CONTRAT<43>/W_EURO)+1/2)     
     ENR_CONTRAT<46>=INT((ENR_CONTRAT<46>/W_EURO)+1/2)
     IF ENR_CONTRAT<66> # "" THEN    
        ENR_CONTRAT<66>=INT((ENR_CONTRAT<66>/W_EURO)+1/2)     
     END
     ENR_CONTRAT<85>=INT((ENR_CONTRAT<85>/W_EURO)+1/2)     
     ENR_CONTRAT<86>=INT((ENR_CONTRAT<86>/W_EURO)+1/2)     

     * CONVERSION RUBRIQUE DE SAISIE
     IF ENR_CONTRAT<89><>"" THEN
	  I=1
	  LOOP
		UNTIL ENR_CONTRAT<89,I>="" DO

		IF ENR_CONTRAT<90,I>="" THEN ENR_CONTRAT<90,I>=0
		IF ENR_CONTRAT<91,I>="" THEN ENR_CONTRAT<91,I>=0

		IF ENR_CONTRAT<90,I><>"0" AND ENR_CONTRAT<91,I><>"0" THEN 
			IF ENR_CONTRAT<91,I><>"0" THEN ENR_CONTRAT<91,I>=INT((ENR_CONTRAT<91,I>/W_EURO)+1/2)
			ENR_CONTRAT<92,I>=INT(((ENR_CONTRAT<90,I>*ENR_CONTRAT<91,I>)/10000)+1/2)
		END ELSE
			IF ENR_CONTRAT<92,I><>"0" THEN ENR_CONTRAT<92,I>=INT((ENR_CONTRAT<92,I>/W_EURO)+1/2)
		END

		I=I+1
	  REPEAT
     END
	
     WRITE ENR_CONTRAT ON F.CONTRAT,CLE
REPEAT

STOP
