SUBROUTINE MAJCOEFFTXHORBEAUVAIS(W_Requete,W_Periode)
***************************************************************
* INTEGRANT LES DONNES POUR LA CCU A PARTIR DES FICHIER EXCEL *
* ALAIN LE 22/05/2003                                         *
***************************************************************

EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"
OPEN "","ASSOCIATION" TO F.ASSOCIATION ELSE STOP
OPEN "","CONTRAT" TO F.CONTRAT ELSE STOP
OPEN "","CONVENTIONCOL" TO F.CONVENTIONCOL ELSE STOP
OPEN "","ETABLISSEMENT" TO F.ETABLISSEMENT ELSE STOP
OPEN "","FUSION" TO F.FUSION ELSE STOP
OPEN "","GRILLESCC" TO F.GRILLESCC ELSE STOP
OPEN "","TAMPONINF" TO F.TAMPONINF ELSE STOP

W_RESULTAT = ""
W_RESULTATCONV = ""

EXECUTE 'SELECT CONVENTIONCOL AVEC 36 = "VRAI"'
EXECUTE 'SAUVE-LISTE W_RESULTATCONV'
EXECUTE "LISTE W_RESULTATCONV" RETURNING MSGCODE

W_Fin = "FAUX"
SELECT F.CONVENTIONCOL TO W_RESULTATCONV
W_CLECONV = ""
W_CONV = ""

LOOP
	READNEXT W_CLECONV FROM W_RESULTATCONV ELSE W_Fin = "VRAI"
WHILE W_Fin = "FAUX" DO
	W_CONV = W_CONV:W_CLECONV:';'
REPEAT

EXECUTE W_Requete
EXECUTE 'SAUVE-LISTE W_RESULTAT'
EXECUTE "LISTE W_RESULTAT" RETURNING MSGCODE

IF MSGCODE<1> # 209 THEN

	SELECT F.CONTRAT TO W_RESULTAT 
	W_FINI = "FAUX"
	W_ANNE = W_Periode[1,4]

	LOOP
		READNEXT W_CLECONT FROM W_RESULTAT ELSE W_FINI = "VRAI"
	WHILE W_FINI = "FAUX" DO

		READ ENR_CONTRAT FROM F.CONTRAT,W_CLECONT ELSE ENR_CONTRAT = ""

	IF INDEX(W_CONV,ENR_CONTRAT<1>:";",1) # 0 THEN

		W_AVENANT = DCOUNT(EXTRACT(ENR_CONTRAT,14),CHAR(253))

		W_DateGrille = OCONV(ENR_CONTRAT<21,W_AVENANT>,"D4/")

		IF W_DateGrille[4,2] = "07" AND W_DateGrille[1,2] # "01" THEN
			W_DateGrille = "01":W_DateGrille[3,8]
			W_DateGrille = ICONV(W_DateGrille,"D4/")
			ENR_CONTRAT<21,W_AVENANT> = W_DateGrille
			WRITE ENR_CONTRAT TO F.CONTRAT,W_CLECONT
		END

		W_PARAMS=""
		W_SORTIE=""
		W_PARAMS<1>=W_CLECONT
		W_PARAMS<2>=W_AVENANT
		W_PARAMS<3>="200307"

		CALL CALCCOEFFTXHOR("",W_PARAMS,W_SORTIE)

		W_COEFF=W_SORTIE<1>
		W_TAUXHOR=W_SORTIE<2>
		W_TAUXHORDIMJF=W_SORTIE<3>

		IF ENR_CONTRAT<20,W_AVENANT> # "" THEN
			* LECTURE FICHIER GRILLESCC
			READ ENR_GRILLESCC FROM F.GRILLESCC,ENR_CONTRAT<20,W_AVENANT> THEN

				IF W_TAUXHOR # 0 THEN
					IF ENR_GRILLESCC<5>="C" THEN
						ENR_CONTRAT<22,W_AVENANT>=W_COEFF
						ENR_CONTRAT<23,W_AVENANT>=W_TAUXHOR
					END ELSE
						ENR_CONTRAT<23,W_AVENANT>=W_TAUXHOR
					END
				END
			END
          
		END

		WRITE ENR_CONTRAT TO F.CONTRAT,W_CLECONT
	END

	REPEAT		
END

RETURN
