OPEN "","PRMOUL" TO F.PR ELSE STOP
OPEN "","_HOLD_" TO F.HOLD ELSE STOP

W_RequeteMoul=""
ENR_HOLD=""

EXECUTE 'SELECT PRMOUL # "_]" AND # "EURO"'

EXECUTE 'SAUVE-LISTE W_RequeteMoul'
EXECUTE "LISTE W_RequeteMoul" RETURNING MSGCODE

IF MSGCODE<1> # 209 THEN

   SELECT F.PR TO W_RequeteMoul

   i=0
   W_Fini="FAUX"
   LOOP
      READNEXT W_Cle FROM W_RequeteMoul ELSE W_Fini="VRAI"
   WHILE W_Fini="FAUX" DO

      i=i+1

      READ ENR_PR FROM F.PR,W_Cle ELSE ENR_PR = ""
      
      W_DateFormat = INDEX(ENR_PR,"DATE.FORMAT",1)	
      W_SetDec = INDEX(ENR_PR,"SET-DEC",1)
      W_SetThous = INDEX(ENR_PR,"SET-THOUS",1)

      ENR_HOLD<i>=W_Cle:SPACE(25-LEN(W_Cle))

      IF W_DateFormat = 0 OR W_SetDec = 0 OR W_SetThous = 0 THEN

         W_1erOpen = INDEX(ENR_PR,"OPEN",1)

         IF W_1erOpen = 0 THEN
             * Pas de OPEN
             W_1erOpen = INDEX(ENR_PR,"SUBROUTINE",1)
             IF W_1erOpen = 0 THEN
                * PAS DE OPEN ni SUBROUTINE on met les EXECUTE en att. 2
                W_Att1erOpen=2
             END ELSE
                * On met les execute aprs la ligne SUBROUTINE
                W_Att1erOpen=DCOUNT(ENR_PR[1,W_1erOpen],CHAR(254))+1
             END

	 END ELSE
            W_Att1erOpen=DCOUNT(ENR_PR[1,W_1erOpen],CHAR(254))
         END


         

	 IF W_DateFormat = 0 THEN
            ENR_PR=INSERT(ENR_PR,W_Att1erOpen;'EXECUTE "DATE.FORMAT"')
            ENR_HOLD<i>=ENR_HOLD<i>:"DATE.FORMAT    "
         END
        
	 IF W_SetDec = 0 THEN
            ENR_PR=INSERT(ENR_PR,W_Att1erOpen;'EXECUTE "SET-DEC ,"')
            ENR_HOLD<i>=ENR_HOLD<i>:"SET-DEC ,      "
         END

	 IF W_SetThous = 0 THEN
            ENR_PR=INSERT(ENR_PR,W_Att1erOpen;'EXECUTE "SET-THOUS ."')
            ENR_HOLD<i>=ENR_HOLD<i>:"SET-THOUS .    "
         END
	
         WRITE ENR_PR ON F.PR,W_Cle

      END

   REPEAT

END

WRITE ENR_HOLD ON F.HOLD,"UniObjectPRMOUL.txt"

EXECUTE 'EFFACER-LISTE W_RequeteMoul'

STOP

* SETPTR 0,,,,,1, "MODE=RAW",DEST \\SERVEURINF\MATRICEPSON,NOHEAD,NOFMT,EJECT,COPIES 1,BRIEF
* PRINTER ON