************************************************
* LISTE LES CONTRATS DE TRAVAIL / SECTEUR      *
* EN INDIQUANT NOM + PRENOM + COEFF DU CONTRAT *
*                                              *
* 11/04/01                            STEPHANE *
************************************************

EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"
OPEN "","CIVILAIDANT" TO F.CIVILAIDANT ELSE STOP
OPEN "","CONTRAT" TO F.CONTRAT ELSE STOP
OPEN "","GRILLESCC" TO F.GRILLESCC ELSE STOP
OPEN "","SECTEUR" TO F.SECTEUR ELSE STOP

W_SECTEUR=""
W_DATEJOUR=DATE()

PRINTER ON

EXECUTE 'SSELECT CONTRAT AVEC 1 = "01" AND AVEC 2 = "001" AND AVEC 7 <= "':W_DATEJOUR:'" AND AVEC 8 >= "':W_DATEJOUR:'" OR = "" PAR SecteurContrat PAR-DECR 22 PAR NomAidantContrat'

W_FINI=0
LOOP
     READNEXT CLE ELSE W_FINI=1
     UNTIL W_FINI=1 DO

     READ ENR_CIVILAIDANT FROM F.CIVILAIDANT,CLE[1,5] ELSE ENR_CIVILAIDANT=""
     READ ENR_CONTRAT FROM F.CONTRAT,CLE ELSE ENR_CONTRAT=""

     IF W_SECTEUR<>ENR_CIVILAIDANT<31> THEN 
	 IF W_SECTEUR<>"" THEN PAGE
	 READ ENR_SECTEUR FROM F.SECTEUR,ENR_CIVILAIDANT<31> ELSE ENR_SECTEUR=""
	 PRINT "**************************************************"
	 PRINT "SECTEUR = ":ENR_SECTEUR<1>    
	 W_SECTEUR=ENR_CIVILAIDANT<31>
     END

     * RECUPERE DERNIER COEFF
     W_NBCOEFF=DCOUNT(ENR_CONTRAT<22>,CHAR(253))

     READ ENR_GRILLESCC FROM F.GRILLESCC,ENR_CONTRAT<20,W_NBCOEFF> ELSE ENR_GRILLESCC<1>="AUCUNE"
     
     * IMPRESSION LISTE
     W_NOM=ENR_CIVILAIDANT<2>:" ":ENR_CIVILAIDANT<3>

     W_NOM=W_NOM[1,40] "L#40"
     ENR_GRILLESCC<1>=ENR_GRILLESCC<1>[1,40] "L#40"

     MONT = (ENR_CONTRAT<22,W_NBCOEFF>/100)
     MONT = MONT "R2"
     MONT = MONT "R(#10)"

     PRINT W_NOM:" - GRILLE : ":ENR_GRILLESCC<1>:" - COEFFICIENT AU ":OCONV(ENR_CONTRAT<15,W_NBCOEFF>,"D4/"):" = ":MONT

REPEAT

PRINTER OFF
