************************************************************
* Liste le personnel prestataire present a la date systeme *
* DA170-01                                                 *
* ALAIN 22/10/2003                                         *
************************************************************

EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"
OPEN "","CIVILAIDANT" TO F.CIVILAIDANT ELSE STOP
OPEN "","CONTRAT" TO F.CONTRAT ELSE STOP
OPEN "","FUSION" TO F.FUSION ELSE STOP

W_RESULTAT = ""
ENR_FUSION = ""

W_REQ = 'SSELECT CONTRAT AVEC 65 # "O" AND AVEC 1 = "01" AND AVEC 7 <= "':DATE():'" AND AVEC 8 => "':DATE():'" OR = "" PAR NomPrenomAidantContrat'

EXECUTE W_REQ
EXECUTE 'SAUVE-LISTE W_RESULTAT' 
EXECUTE "LISTE W_RESULTAT" RETURNING MSGCODE

IF MSGCODE<1> # 209 THEN

	W_FINI = "FAUX"
	W_AIDANT=""
	CLE.CONTRAT=""
	ENR_FUSION = ""
	I = 1
	GOSUB 10

	SELECT F.CONTRAT TO W_RESULTAT

    	LOOP
		READNEXT CLE.CONTRAT FROM W_RESULTAT ELSE W_FINI="VRAI"
	WHILE W_FINI = "FAUX" DO
		I = I + 1
		W_AIDANT = CLE.CONTRAT[1,5]
		READ ENR_CIVILAIDANT FROM F.CIVILAIDANT,W_AIDANT ELSE ENR_CIVILAIDANT = ""
		READ ENR_CONTRAT FROM F.CONTRAT,CLE.CONTRAT ELSE ENR_CONTRAT = ""
		
		*Donnes aidant 
		GOSUB 100
		ENR_FUSION<I,1> = W_AIDANT
		ENR_FUSION<I,2> = W_Nom
		ENR_FUSION<I,3> = W_Adr1
		ENR_FUSION<I,4> = W_Adr2	
		ENR_FUSION<I,5> = W_CP
		ENR_FUSION<I,6> = W_Ville
		ENR_FUSION<I,7> = ENR_CIVILAIDANT<12>
		ENR_FUSION<I,8> = ENR_CIVILAIDANT<14>
		ENR_FUSION<I,9> = OCONV(ENR_CONTRAT<7>,"D4/")
		ENR_FUSION<I,10> = OCONV(ENR_CIVILAIDANT<26>,"D4/")
		
	REPEAT

	CONVERT CHAR(253) TO ';' IN ENR_FUSION
	W_CLEFUSION = 'LISTEPERSONNEL.CSV'

	WRITE ENR_FUSION TO F.FUSION,W_CLEFUSION

END ELSE

	PRINT 'AUCUNE DONNES DISPONIBLE POUR CE TYPE DE PERSONNEL'

END

STOP

10
******************************
* GENRATION LIGNE DE LIBELLE *
******************************

ENR_FUSION<I,1> = 'code aidant'
ENR_FUSION<I,2> = 'nom-prnom aidant'
ENR_FUSION<I,3> = '1ere ligne adresse'
ENR_FUSION<I,4> = 'complment adresse'
ENR_FUSION<I,5> = 'code postal'
ENR_FUSION<I,6> = 'commune'
ENR_FUSION<I,7> = 'Tlphone 1'
ENR_FUSION<I,8> = 'Tlphone 2'
ENR_FUSION<I,9> = 'date dbut contrat'
ENR_FUSION<I,10> = 'date de naissance'

RETURN
100
*************************************************
* 		Donnes aidant			      *
*************************************************
W_Nom = ""
W_Adr1 = ""
W_Adr2 = ""
W_CP = ""
W_Ville = ""

W_Nom = ENR_CIVILAIDANT<2>:' ':ENR_CIVILAIDANT<3>
W_Adr1 = TRIM(ENR_CIVILAIDANT<5>:" ":ENR_CIVILAIDANT<6>:" ":ENR_CIVILAIDANT<7>:" ":ENR_CIVILAIDANT<8>)
W_Adr2 = TRIM(ENR_CIVILAIDANT<9>)
IF W_Adr1 = "" THEN
	W_Adr1 = W_Adr2
	W_Adr2 = ""
END
CONVERT ";" TO ' ' IN W_Adr1
CONVERT ";" TO ' ' IN W_Adr2

W_CP = ENR_CIVILAIDANT<10>
W_Ville = ENR_CIVILAIDANT<11>

RETURN
