* Ouverture d'un fichier
EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"
OPEN "","ACCORD" TO F.ACCORD ELSE STOP
OPEN "","CIVILAIDANT" TO F.CIVILAIDANT ELSE STOP
OPEN "","CIVILAIDE" TO F.CIVILAIDE ELSE STOP
OPEN "","HRESHISTOR" TO F.HRESHISTOR ELSE STOP
OPEN "","HRESAIDANT" TO F.HRESAIDANT ELSE STOP

PRINT "Saisissez la periode  traiter (AAMM) :"
INPUT W_PerTrait

MOIS = W_PerTrait[3,2]
AN = W_PerTrait[1,2]
ANF = AN

MOISDEB = MOIS
MOISFIN = MOIS + 1

IF MOISFIN > 12 THEN
	MOISFIN = MOISFIN - 12
	ANF = ANF + 1
END

MOISDEB = MOISDEB "R(%2)"
MOISFIN = MOISFIN "R(%2)"

W_DATEDEB = ICONV("01/":MOISDEB:"/20":AN,"D4/")
W_DATEFIN = ICONV("01/":MOISFIN:"/20":ANF,"D4/")
W_DATEFIN= W_DATEFIN - 1

* Requete
EXECUTE 'SELECT ACCORD AVEC 1 = "001" AND AVEC 18 = "" AND AVEC 5 <= "':W_DATEFIN:'" AND AVEC 6 => "':W_DATEDEB:'" AND AVEC DateSortieAideAccord => "':W_DATEDEB:'" OR = "" PAR NomAide PAR PrenomAide'
EXECUTE 'SAUVE-LISTE W_RESULTAT'
EXECUTE "LISTE W_RESULTAT" RETURNING MSGCODE

ENR_HRESHISTOR = ""

IF MSGCODE<1> # 209 THEN

	SELECT F.ACCORD TO W_RESULTAT
	W_Fini="FAUX"
	W_CleAnc = ""

	* Parcours de la requete
	LOOP
		READNEXT W_Cle FROM W_RESULTAT ELSE W_Fini="VRAI"
	WHILE W_Fini="FAUX" DO

		IF W_Cle[1,5] # W_CleAnc THEN
			W_CleAnc = W_Cle[1,5]
			W_Cle = W_CleAnc:"00120":W_PerTrait
			READ ENR_HRESHISTOR FROM F.HRESHISTOR,W_Cle ELSE ENR_HRESHISTOR<1> = "VIDE"
			READ ENR_CIVILAIDE FROM F.CIVILAIDE,W_CleAnc ELSE ENR_CIVILAIDE = ""
			IF ENR_HRESHISTOR<1> # "VIDE" THEN
				
				W_Nom = ENR_CIVILAIDE<2>:" ":ENR_CIVILAIDE<3>
				W_Nom = W_Nom[1,44]
				W_Nom = W_Nom:SPACE(45-(LEN(W_Nom)))
				I=1
				LOOP
				WHILE ENR_HRESHISTOR<1,I> # "" DO
					W_CleAidant = ENR_HRESHISTOR<1,I>:"00120":W_PerTrait
					READ ENR_HRESAIDANT FROM F.HRESAIDANT,W_CleAidant ELSE ENR_HRESAIDANT = ""
					READ ENR_CIVILAIDANT FROM F.CIVILAIDANT,ENR_HRESHISTOR<1,I> ELSE ENR_CIVILAIDANT = "VIDE"
					W_NomAidant = ENR_CIVILAIDANT<2>:" ":ENR_CIVILAIDANT<3>
					W_NomAidant = W_NomAidant[1,44]
					ENR_HRESAIDANT<1> = ENR_HRESHISTOR<1,I>
					ENR_HRESAIDANT<2> = W_NomAidant:SPACE(45-(LEN(W_NomAidant)))
					ENR_HRESAIDANT<3,-1> = W_Cle[1,5]:" ":W_Nom
					HRES = (ENR_HRESHISTOR<2,I>/100)
					HRES = HRES "R2"
					HRES = HRES "R(#6)"
					ENR_HRESAIDANT<4,-1> = HRES
			   		WRITE ENR_HRESAIDANT ON F.HRESAIDANT,W_CleAidant
					I=I+1
			   	REPEAT

			END
		END
	REPEAT
END

EXECUTE 'TRIER HRESAIDANT AVEC @ID = "[':W_PerTrait:'" PAR 2 1 2 3 4 SUPP-ID (P'

STOP
