OPEN "","CONTRAT" TO F.CONTRAT ELSE STOP
OPEN "","CIVILAIDANT" TO F.CIVILAIDANT ELSE STOP
OPEN "","FUSION" TO F.FUSION ELSE STOP
EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"
PRINT "Exportation du suivi de contrat sous Excel (*.csv)"
PRINT "Periode de fin de modulation (AAAAMM) ?"
INPUT W_PERIODE
IF W_PERIODE MATCH "6N" THEN NULL ELSE STOP
PRINT "Association (3N)"
INPUT W_ASSO
IF W_ASSO MATCH "3N" THEN NULL ELSE STOP

ENR = ""
W_IND=1
ENR<W_IND> = "Code;Nom aidant;Heures reelles;Heures contrat;Solde;Heures majorees;Taux horaire;Cot"

EXECUTE 'SELECT CONTRAT AVEC 1 = "01" AND AVEC 5 = "M" AND AVEC 6 = "P" AND AVEC 2 = "':W_ASSO:'" AND AVEC 65 # "O" AND AVEC 71 = "':W_PERIODE:'" AND AVEC 8 = "" OR >= "14246" PAR NomPrenomAidantContrat'

W_FINI = "NON"
LOOP
READNEXT W_CLE ELSE W_FINI = "OUI"
UNTIL W_FINI = "OUI"
   READ ENR_CONTRAT FROM F.CONTRAT, W_CLE THEN
	READ ENR_CIVILAIDANT FROM F.CIVILAIDANT, W_CLE[1,5] ELSE ENR_CIVILAIDANT=""
	W_PARAMS=""
	W_SORTIE=""
	W_PARAMS<1>=W_CLE
	W_PARAMS<2>="0"
	W_PARAMS<3>=W_PERIODE
	CALL CALCCOEFFTXHOR("",W_PARAMS,W_SORTIE)
	IF W_SORTIE<2> # "" THEN
	   W_TAUX=W_SORTIE<2>
	   IF W_TAUX<8270 THEN W_TAUX=8270
	END ELSE
	   W_TAUX=0
	END
	I=1
	CUMHHREELLES=0
	CUMHHCONTRAT=0
	SOLDEHH=00
	LOOP
	   PERPRECSUIVCONTRAT=ENR_CONTRAT<71,I>
	   UNTIL PERPRECSUIVCONTRAT="" DO
		CUMHHCONTRAT=CUMHHCONTRAT+ENR_CONTRAT<72,I>-ENR_CONTRAT<73,I>
		CUMHHREELLES=CUMHHREELLES+ENR_CONTRAT<74,I>
		SOLDEHH=SOLDEHH+ENR_CONTRAT<75,I>
		I=I+1
	REPEAT
	HH10POURCENT=INT(CUMHHCONTRAT*110/100+1/2)
	HHMAJOREES=0
	IF CUMHHREELLES>HH10POURCENT THEN HHMAJOREES=CUMHHREELLES-HH10POURCENT
	COUTHHMAJOREES=INT(HHMAJOREES*W_TAUX/1000+1/2)
	W_IND=W_IND+1
	ENR<W_IND>=W_CLE[1,5]:";":ENR_CIVILAIDANT<2>:" ":ENR_CIVILAIDANT<3>:";":CUMHHREELLES/100:";":CUMHHCONTRAT/100:";":SOLDEHH/100:";":HHMAJOREES/100:";":W_TAUX/1000:";":COUTHHMAJOREES/100
   END
REPEAT
WRITE ENR ON F.FUSION, "ListeSuivContrats.csv"
PRINT "Le fichier ListeSuivContrats.csv a t gnr dans le rpertoire FUSION de la base de donnes."
STOP