******************************************************
* DIFFERENCE ENTRE BALANCEGENE ET DETAILECRITUREGENE *
* SUR LES ECRITURES NON LETTREES
*
* ALAIN 12/10/2001                                   *
******************************************************

EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"
OPEN "","DETAILECRITUREGENE" TO F.DETAILECRITUREGENE ELSE STOP
OPEN "","BALANCEGENE" TO F.BALANCEGENE ELSE STOP

EXECUTE 'SSELECT DETAILECRITUREGENE AVEC 11 = "" PAR 3 PAR ExerciceDetailEcrGene '

W_FINI = "FAUX"	
DIFBAL = 0
DIFDET = 0
DIFDETDEB = 0
DIFDETCRE = 0
ANCCLE = ""
CPTE = ""
CPTEBAL = ""

PRINTER ON

LOOP
	READNEXT CLE ELSE W_FINI = "VRAI"
	CLEDET = CLE[6,2]
WHILE W_FINI = "FAUX"

	READ ENR_DETAILECRITUREGENE FROM F.DETAILECRITUREGENE,CLE ELSE ENR_DETAILCALCUL = ""
	
	IF (ANCCLE # CLEDET) OR (ENR_DETAILECRITUREGENE<3> # CPTE) THEN
		IF ANCCLE # "" THEN
			CPTEBAL = ANCCLE:CPTE
			READ ENR_BALANCEGENE FROM F.BALANCEGENE,CPTEBAL ELSE ENR_BALANCEGENE = ""
			DIFBAL = ENR_BALANCEGENE<1> - ENR_BALANCEGENE<2>
			DIFDET = DIFDETDEB - DIFDETCRE
			IF DIFBAL # DIFDET THEN
				DIFBAL = DIFBAL / 100
				DIFDET = DIFDET / 100
				DIFBAL = DIFBAL "R2"
				DIFDET = DIFDET "R2"
				DIFBAL = DIFBAL "R(#10)"
				DIFDET = DIFDET "R(#10)"
				PRINT CPTE:' ':DIFDET:' ':DIFBAL:' ':ANCCLE
			END
			DIFBAL = 0
			DIFDET = 0
			DIFDETDEB = 0
			DIFDETCRE = 0
		END ELSE
			PRINT '    COMPTE      DETAIL     BALANCE  EX'
		END
		ANCCLE = CLEDET
		CPTE = ENR_DETAILECRITUREGENE<3>
	END
	
	IF ENR_DETAILECRITUREGENE<6> # "" THEN
		DIFDETDEB = DIFDETDEB + ENR_DETAILECRITUREGENE<6>
	END
	
	IF ENR_DETAILECRITUREGENE<7> # "" THEN
		DIFDETCRE = DIFDETCRE + ENR_DETAILECRITUREGENE<7>
	END

REPEAT

CPTEBAL = ANCCLE:CPTE
READ ENR_BALANCEGENE FROM F.BALANCEGENE,CPTEBAL ELSE ENR_BALANCEGENE = ""
DIFBAL = ENR_BALANCEGENE<1> - ENR_BALANCEGENE<2>
DIFDET = DIFDETDEB - DIFDETCRE
IF DIFBAL # DIFDET THEN
	DIFBAL = DIFBAL / 100
	DIFDET = DIFDET / 100
	DIFBAL = DIFBAL "R2"
	DIFDET = DIFDET "R2"
	DIFBAL = DIFBAL "R(#10)"
	DIFDET = DIFDET "R(#10)"
	PRINT CPTE:' ':DIFDET:' ':DIFBAL:' ':ANCCLE
END

STOP
