*PARAMETRES*
*Liste des personnes  charge des aidants actifs*
*Code entit juridique (par exemple 001) |3N|TXT|O*
*Date de rfrence (sous la forme JJ/MM/AAAA) |10X|TXT|O*
*FIN PARAMETRES*

SUBROUTINE LISTEPERSCHG(RETURNVAL,PARAMETRES,W_Sortie)
***********************************
*	Liste des enfants des aidants *
*                                 *
* Grgory - 08/10/10              *
***********************************
EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"
OPEN "","CIVILAIDANT" TO F.CIVILAIDANT ELSE RETURN
OPEN "","FUSION" TO F.FUSION ELSE RETURN
OPEN "","CONTRAT" TO F.CONTRAT ELSE RETURN
OPEN "","SECTEUR" TO F.SECTEUR ELSE RETURN

W_Asso=PARAMETRES<1>
W_DateRef=ICONV(PARAMETRES<2>,"D4/")

ENR_CIVILAIDANT=""
ENR_FUSION=""
ENR_CONTRAT=""
ENR_SECTEUR=""

ENR_FUSION<1>="Secteur;Code aidant;Nom prenom;Adresse;Compl adresse;Code postal;Commune;Fonction;Type de contrat;Nom personne  charge;Prnom personne  charge;Date nais. personne  charge;Lien personne  charge"

W_Contrats=""
EXECUTE 'SELECT CONTRAT AVEC 7 <= "':W_DateRef:'" AND AVEC 8 >= "':W_DateRef:'" OR = "" AND AVEC 1 <> "02" AND AVEC 65 <> "O" AND AVEC 2 = "':W_Asso:'" PAR LibSecteurContrat PAR NomPrenomAidantContrat'
EXECUTE 'SAUVE-LISTE W_Contrats'
EXECUTE 'LISTE W_Contrats' RETURNING MSGCODE

IF MSGCODE<1> # "209" THEN
	SELECT F.CONTRAT TO W_Contrats

	W_Fin = "F"
	LOOP
		READNEXT W_Cle FROM W_Contrats ELSE W_Fin = "O"
	WHILE W_Fin = "F"		
		READ ENR_CONTRAT FROM F.CONTRAT, W_Cle THEN
			READ ENR_CIVILAIDANT FROM F.CIVILAIDANT, W_Cle[1,5] THEN
				READ ENR_SECTEUR FROM F.SECTEUR, ENR_CIVILAIDANT<31> ELSE ENR_SECTEUR=""
				
				W_NumVoie=""
				W_ComplNumVoie=""
				W_NatVoie=""
				W_NomVoie=""
				
				IF ENR_CIVILAIDANT<5><>"" THEN W_NumVoie=ENR_CIVILAIDANT<5>:' '
				IF ENR_CIVILAIDANT<6><>"" THEN W_ComplNumVoie=ENR_CIVILAIDANT<6>:' '
				IF ENR_CIVILAIDANT<7><>"" THEN W_NatVoie=ENR_CIVILAIDANT<7>:' '
				IF ENR_CIVILAIDANT<8><>"" THEN W_NomVoie=ENR_CIVILAIDANT<8>
				
				IF ENR_CONTRAT<6>="A" THEN
					W_Fonction="Administratif"
				END ELSE
					W_Fonction="Production"
				END
				
				FOR I = 1 TO DCOUNT(ENR_CIVILAIDANT<22>,CHAR(253))
					W_Lien=""
					IF ENR_CIVILAIDANT<25,I>="1" THEN W_Lien="Enfant"
					IF ENR_CIVILAIDANT<25,I>="2" THEN W_Lien="Grand-parent"
					IF ENR_CIVILAIDANT<25,I>="3" THEN W_Lien="Parent"
					IF ENR_CIVILAIDANT<25,I>="4" THEN W_Lien="Petit-enfant"
					IF ENR_CIVILAIDANT<25,I>="5" THEN W_Lien="Conjoint(e)"

					ENR_FUSION<-1>=ENR_SECTEUR<1>:';':W_Cle[1,5]:';':ENR_CIVILAIDANT<2>:' ':ENR_CIVILAIDANT<3>:';':W_NumVoie:W_ComplNumVoie:W_NatVoie:W_NomVoie:';':ENR_CIVILAIDANT<9>:';':ENR_CIVILAIDANT<10>:';':ENR_CIVILAIDANT<11>:';':W_Fonction:';':ENR_CONTRAT<4>:';':ENR_CIVILAIDANT<22,I>:';':ENR_CIVILAIDANT<23,I>:';':OCONV(ENR_CIVILAIDANT<24,I>,"D4/"):';':W_Lien
				NEXT I
			END
		END
	REPEAT
END

EXECUTE "EFFACER-LISTE W_Contrats"

IF ENR_FUSION<2><>"" THEN
	W_DateClaire=OCONV(W_DateRef,"D4/")[7,4]:'-':OCONV(W_DateRef,"D4/")[4,2]:'-':OCONV(W_DateRef,"D4/")[1,2]
	W_Fichier="Liste des personnes  charges - Aidants actifs au ":W_DateClaire:".csv"
	WRITE ENR_FUSION ON F.FUSION,W_Fichier
	
	W_Sortie='Le fichier "':W_Fichier:'" a t gnr dans le rpertoire FUSION de la base de donnes.'
END ELSE
	W_Sortie="Aucun aidant trouv."
END

RETURN