*PARAMETRES*
*Liste des interventions des aids en doublon pour un aidant*
*Priode de traitement (sous la forme AAAAMM) |6N|TXT|O*
*FIN PARAMETRES*

SUBROUTINE INTERVDOUBLON(RETURNVAL,PARAMETRES,W_Sortie)

EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"

W_Periode=PARAMETRES<1>

*************************************************************
*	TRAITEMENT POUR LISTER LES INTERVENTIONS DES AIDES 		*
*   EN DOUBLON POUR UN AIDANT								*
* --------------------------------------------------------- *
* VANESSA									 	MARS 2009 	*
*************************************************************

OPEN "","CIVILAIDANT" TO F.CIVILAIDANT ELSE PRINT "ERREUR OUVERTURE CIVILAIDANT"
OPEN "","CIVILAIDE" TO F.CIVILAIDE ELSE PRINT "ERREUR OUVERTURE CIVILAIDE"
OPEN "","TPSTEMPO" TO F.TEMPO ELSE PRINT "ERREUR OUVERTURE TEMPO"
OPEN "","FUSION" TO F.FUSION ELSE PRINT "ERREUR OUVERTURE FUSION"
OPEN "","SECTEUR" TO F.SECTEUR ELSE PRINT "ERREUR OUVERTURE SECTEUR"

W_Mois=W_Periode[5,2]
W_An=W_Periode[1,4]
DATEDEB=ICONV("01/":W_Mois:"/":W_An,"D4/")
W_Mois=W_Mois+1
IF W_Mois="13" THEN
	W_Mois="01"
	W_An=W_An+1
END
DATEFIN=ICONV("01/":W_Mois:"/":W_An,"D4/")-1

EXECUTE 'AFFICHEPLANNING |INTERVDOUBLON||PM|':DATEDEB:'|':DATEFIN:'||||E'

W_Fichier=""
W_Fichier<1>="Code aidant;Nom aidant;Secteur aidant;Jour Interv;Code aide 1;Nom aide 1;Secteur aide 1;Hre debut 1;Hre fin 1;Code aide 2;Nom aide 2;Secteur aide 2;Hre debut 2;Hre fin 2"
W_Indice=2

**On lit le fichier gnr par le pr afficheplanning
READ ENR_TEMPO FROM F.TEMPO,"AFFICHEPLANNINGINTERVDOUBLON" THEN

	FOR i=1 TO DCOUNT(ENR_TEMPO,CHAR(254))
		IF ENR_TEMPO<i>[1,7]="#Interv" THEN
			W_CodeAidant=ENR_TEMPO<i>[8,5]
			READ ENR_CIVILAIDANT FROM F.CIVILAIDANT,W_CodeAidant ELSE ENR_CIVILAIDANT=""
			READ ENR_SECTEURAIDANT FROM F.SECTEUR,ENR_CIVILAIDANT<31> ELSE ENR_SECTEUR=""
			W_Jour=0
		END ELSE
			W_Jour=W_Jour+1
			W_JourMois=ICONV(W_Jour:"/":W_Periode[5,2]:"/":W_Periode[1,4],"D4/")
			GOSUB 20
		END
	NEXT i
END

IF W_Fichier<2># "" THEN
	WRITE W_Fichier ON F.FUSION,"INTERVDOUBLON.csv"

	W_Sortie="Gnration du fichier 'INTERVDOUBLON.csv' termine dans le rpertoire FUSION."
END ELSE
	W_Sortie="Pas de doublon."
END

RETURN

****************************************************************************
* Recherche 2 interventions qui se chevauchent
20

	W_Count=DCOUNT(ENR_TEMPO<i,1>,CHAR(252))
	FOR y=1 TO W_Count
		FOR z=y+1 TO W_Count
			W_HreDeb1=ENR_TEMPO<i,2,y>
			W_HreFin1=ENR_TEMPO<i,3,y>
			W_HreDeb2=ENR_TEMPO<i,2,z>
			W_HreFin2=ENR_TEMPO<i,3,z>
			IF INT(W_HreFin1) > INT(W_HreDeb2) THEN
				W_CodeAide1=ENR_TEMPO<i,4,y>[6,5]
				READ ENR_CIVILAIDE1 FROM F.CIVILAIDE,W_CodeAide1 ELSE ENR_CIVILAIDE1=""
				READ ENR_SECTEURAIDE1 FROM F.SECTEUR, ENR_CIVILAIDE1<40>[1,3] ELSE ENR_SECTEURAIDE1=""
				W_CodeAide2=ENR_TEMPO<i,4,z>[6,5]
				READ ENR_CIVILAIDE2 FROM F.CIVILAIDE,W_CodeAide2 ELSE ENR_CIVILAIDE2=""
				READ ENR_SECTEURAIDE2 FROM F.SECTEUR, ENR_CIVILAIDE2<40>[1,3] ELSE ENR_SECTEURAIDE2=""
				
				W_Temp=W_CodeAidant:";":ENR_CIVILAIDANT<2>:" ":ENR_CIVILAIDANT<3>:";":ENR_SECTEURAIDANT<1>:";":OCONV(W_JourMois,"D4/"):";"
				W_Temp=W_Temp:W_CodeAide1:";":ENR_CIVILAIDE1<2>:" ":ENR_CIVILAIDE1<3>:";":ENR_SECTEURAIDE1<1>:";":W_HreDeb1:";":W_HreFin1:";"
				W_Temp=W_Temp:W_CodeAide2:";":ENR_CIVILAIDE2<2>:" ":ENR_CIVILAIDE2<3>:";":ENR_SECTEURAIDE2<1>:";":W_HreDeb2:";":W_HreFin2
				W_Fichier<W_Indice>=W_Temp
				W_Indice=W_Indice+1
			END
		NEXT z
	NEXT y
	
RETURN
