*PARAMETRES*
*Heures aidant/aid saisie dtaille*
*Priode (AAAAMM) |6N|TXT|O*
*FIN PARAMETRES*

SUBROUTINE HRESAIDANTAIDESAISIEDETAILLEE(RETURNVAL,PARAMETRES,W_Sortie)
EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"
*********************************************************************
* 
*********************************************************************
OPEN "","STATAIDE" TO F.STATAIDE ELSE RETURN
OPEN "","DETAILPREST" TO F.DETAILPREST ELSE RETURN
OPEN "","CIVILAIDANT" TO F.CIVILAIDANT ELSE RETURN
OPEN "","CIVILAIDE" TO F.CIVILAIDE ELSE RETURN
OPEN "","SECTEUR" TO F.SECTEUR ELSE RETURN
OPEN "","CONTRAT" TO F.CONTRAT ELSE RETURN
OPEN "","AGGIRAIDE" TO F.AGGIRAIDE ELSE RETURN
OPEN "","RUBSAISIE" TO F.RUBSAISIE ELSE RETURN
OPEN "","ACTIVITES" TO F.ACTIVITES ELSE RETURN
*********************************************************************

W_Periode=PARAMETRES<1>
W_DernJourPer=ICONV( "01":OCONV(ICONV("01/":W_Periode[5,2]:"/":W_Periode[1,4],"D4/")+32,"D4/")[3,8],"D4/")-1

IF W_DernJourPer="" OR LEN(W_Periode)<>6 THEN
	W_Sortie="Aucun fichier gnr : priode incorrecte."
	RETURN
END

ENR_STATAIDE=""
ENR_DETAILPREST=""
ENR_CIVILAIDANT=""
ENR_CIVILAIDE=""
ENR_SECTEURAIDANT=""
ENR_SECTEURAIDE=""
ENR_CONTRAT=""
ENR_AGGIRAIDE=""
ENR_RUBSAISIE=""
ENR_ACTIVITES=""

W_Req=""

*********************************************************************

	ENR_STATAIDE<-1>="Code aidant;Nom prenom aidant;Commune aidant;Secteur aidant;Categorie aidant;Heures contrat;Code aide;Nom prenom aide;Commune aide;Secteur aide;Code GIR aide;Jour;Heures effectuees;Rub. de saisie;Activite;Periode"

	EXECUTE 'SELECT DETAILPREST AVEC 0 = "[':W_Periode:'" PAR NomPrenomAidantDetailPrest'
	EXECUTE 'SAUVE-LISTE W_Req'
	EXECUTE 'LISTE W_Req' RETURNING MSGCODE

	IF MSGCODE<1> # "209" THEN
		SELECT F.DETAILPREST TO W_Req

		W_Fin = "F"
		LOOP
			READNEXT W_Cle FROM W_Req ELSE W_Fin = "O"
		WHILE W_Fin = "F"
			READ ENR_DETAILPREST FROM F.DETAILPREST, W_Cle THEN
				READ ENR_CIVILAIDANT FROM F.CIVILAIDANT, W_Cle[1,5] ELSE ENR_CIVILAIDANT=""
				READ ENR_SECTEURAIDANT FROM F.SECTEUR, ENR_CIVILAIDANT<31> ELSE ENR_SECTEURAIDANT=""
				READ ENR_CONTRAT FROM F.CONTRAT, W_Cle[1,8] ELSE ENR_CONTRAT=""
				
				W_Cat=""
				W_HresContrat=""
				W_Freq=""
				
				FOR J = DCOUNT(ENR_CONTRAT<15>,CHAR(253)) TO 1 STEP -1
					IF ENR_CONTRAT<15,J><= W_DernJourPer THEN
						W_Cat=ENR_CONTRAT<16,J>
						W_HresContrat=ENR_CONTRAT<24,J>
						W_Freq=ENR_CONTRAT<25,J>
						
						BEGIN CASE
							CASE W_Freq="1"
								W_HresContrat=INT(((W_HresContrat*52)/12)+(1/2))/100
							CASE W_Freq="2"
								W_HresContrat=INT(((W_HresContrat*26)/12)+(1/2))/100
							CASE W_Freq="3"
								W_HresContrat=W_HresContrat/100
							CASE W_Freq="4"
								W_HresContrat=INT((W_HresContrat/12)+(1/2))/100
						END CASE
						EXIT
					END
				NEXT J
				
				FOR I = 1 TO DCOUNT(ENR_DETAILPREST<1>,CHAR(253))
					READ ENR_CIVILAIDE FROM F.CIVILAIDE, ENR_DETAILPREST<1,I> ELSE ENR_CIVILAIDE=""
					READ ENR_SECTEURAIDE FROM F.SECTEUR, ENR_CIVILAIDE<40>[1,3] ELSE ENR_SECTEURAIDE=""
					READ ENR_AGGIRAIDE FROM F.AGGIRAIDE, ENR_DETAILPREST<1,I> ELSE ENR_AGGIRAIDE=""

					W_CodeGir=""
					
					IF ENR_AGGIRAIDE<18> <= W_DernJourPer THEN
						W_CodeGir=ENR_AGGIRAIDE<19>:ENR_AGGIRAIDE<20>
					END ELSE
						FOR J = 1 TO DCOUNT(ENR_AGGIRAIDE<39>,CHAR(253))
							IF ENR_AGGIRAIDE<39,J><=W_DernJourPer THEN
								W_CodeGir=ENR_AGGIRAIDE<40,J>:ENR_AGGIRAIDE<41,J>
								EXIT
							END
						NEXT J
						IF W_CodeGir= "" THEN
							W_CodeGir=ENR_AGGIRAIDE<19>:ENR_AGGIRAIDE<20>
						END
					END					
					
					FOR J = 1 TO DCOUNT(ENR_DETAILPREST<10,I>,CHAR(252))
						W_Jour = ENR_DETAILPREST<10,I,J>
						W_HresDetail=ENR_DETAILPREST<12,I,J>/100
						READ ENR_RUBSAISIE FROM F.RUBSAISIE, ENR_DETAILPREST<11,I,J> ELSE ENR_RUBSAISIE=""
						READ ENR_ACTIVITES FROM F.ACTIVITES, ENR_DETAILPREST<13,I,J> ELSE ENR_ACTIVITES=""						

						ENR_STATAIDE<-1>=W_Cle[1,5]:';':ENR_CIVILAIDANT<2>:' ':ENR_CIVILAIDANT<3>:';':ENR_CIVILAIDANT<11>:';':ENR_SECTEURAIDANT<1>:';':W_Cat:';':W_HresContrat:';':ENR_DETAILPREST<1,I>:';':ENR_CIVILAIDE<2>:' ':ENR_CIVILAIDE<3>:';':ENR_CIVILAIDE<11>:';':ENR_SECTEURAIDE<1>:';':W_CodeGir:';':W_Jour:';':W_HresDetail:';':ENR_RUBSAISIE<1>:';':ENR_ACTIVITES<1>:';':W_Periode[5,2]:"/":W_Periode[1,4]
					NEXT J
				NEXT I
			END
		REPEAT
		
		WRITE ENR_STATAIDE ON F.STATAIDE, "HRESAIDANTAIDE-":W_Periode:".csv"
		W_Sortie="Fichier HRESAIDANTAIDE-":W_Periode:" gnr dans le rpertoire STATAIDE."
	END ELSE
		W_Sortie='Aucune donne sur la priode renseigne.'
	END

RETURN