***********************************************************
*
* TRANSPOSITION DU FICHIER FORMATION DU MODULE PAIE PRINCIPAL 
* VERS FICHIER FORMEXPAIDANT
* SI PRESENCE GESTEMPS ON NE FAIT RIEN
*
* MAI 2000                                  DIDIER
***********************************************************
EXECUTE 'DATE.FORMAT'
OPEN "","PARAMASSO" TO F.PARAMASSO ELSE STOP
READ ENRPARAMASSO FROM F.PARAMASSO,"1" ELSE STOP
I=1
PRESENCEGESTEMPS=0
LOOP
 COMPTE=EXTRACT(ENRPARAMASSO,1,I)
 UNTIL COMPTE="" DO
  IF COMPTE="GESTEMPS" THEN PRESENCEGESTEMPS=1
  I=I+1
REPEAT
IF PRESENCEGESTEMPS=1 THEN STOP

PROCREAD VARIABLES ELSE STOP
MODULE=FIELD(VARIABLES," ",2)
IF MODULE="PAIE" OR MODULE="PAIEAM" THEN NULL ELSE STOP

OPEN "","VOC" TO F.VOC ELSE STOP
ENRVOC=""
ENRVOC=REPLACE(ENRVOC,1;"F")
CHEMIN="D:\TRANSFERT\":MODULE
ENRVOC=REPLACE(ENRVOC,2;CHEMIN:"\FORMATION")
ENRVOC=REPLACE(ENRVOC,3;CHEMIN:"\D_FORMATION")
WRITE ENRVOC ON F.VOC,"FORMATION"
ENRVOC=REPLACE(ENRVOC,2;CHEMIN:"\FIPAY")
ENRVOC=REPLACE(ENRVOC,3;CHEMIN:"\D_FIPAY")
WRITE ENRVOC ON F.VOC,"FIPAY"
ENRVOC=REPLACE(ENRVOC,2;CHEMIN:"\PARAM.FORM")
ENRVOC=REPLACE(ENRVOC,3;CHEMIN:"\D_PARAM.FORM")
WRITE ENRVOC ON F.VOC,"PARAM.FORM"
OPEN "","FORMATION" TO F.FORMATION ELSE STOP
OPEN "","FIPAY" TO F.FIPAY ELSE STOP
OPEN "","PARAM.FORM" TO F.PARAMFORM ELSE STOP
OPEN "","TABLES" TO F.TABLES ELSE STOP
OPEN "","FORMEXPAIDANT" TO F.FORMEXPAIDANT ELSE STOP

**************************************************************
* FICHIER TABLES CLE "FORMPRO" A REMPLIR A PARTIR DE PARAM.FORM
**************************************************************

* FORMATION PROFESSIONNELLE
READ ENR_TABLES FROM F.TABLES,"FORMPRO" ELSE ENR_TABLES=""
ENR_TABLES<2>=""
ENR_TABLES<3>=""
EXECUTE "TSELECT PARAM.FORM"
FINI="NON"
LOOP
 READNEXT CLEFORM ELSE FINI="OUI"
 UNTIL FINI="OUI" DO
   READ ENR_PARAMFORM FROM F.PARAMFORM,CLEFORM ELSE ENR_PARAMFORM=""
   CLEFORM="0":CLEFORM
   LIBFORM=EXTRACT(ENR_PARAMFORM,1)
   ENR_TABLES=REPLACE(ENR_TABLES,2,-1;CLEFORM)
   ENR_TABLES=REPLACE(ENR_TABLES,3,-1;LIBFORM)
REPEAT
WRITE ENR_TABLES ON F.TABLES,"FORMPRO"

****************************************************************************
* 2 eme partie : Contruction du fichier FORMEXPAIDANT
****************************************************************************

EXECUTE 'TSELECT FORMATION'

W_FINI="NON"
LOOP
 READNEXT CLESAL ELSE W_FINI="OUI"
 UNTIL W_FINI="OUI" DO
 READ ENR_FORMATION FROM F.FORMATION,CLESAL ELSE ENR_FORMATION=""
 READ ENR_FIPAY FROM F.FIPAY,CLESAL ELSE ENR_FIPAY=""

 ENR_FORMEXPAIDANT=""
 ENR_FORMEXPAIDANT<1>="D"
 W_Count=DCOUNT(ENR_FORMATION<1>,CHAR(253))
 FOR i=1 TO W_Count
  ENR_FORMEXPAIDANT=REPLACE(ENR_FORMEXPAIDANT,5,i;ENR_FORMATION<3,i>)
  ENR_FORMEXPAIDANT=REPLACE(ENR_FORMEXPAIDANT,6,i;"0":ENR_FORMATION<1,i>)
  ENR_FORMEXPAIDANT=REPLACE(ENR_FORMEXPAIDANT,7,i;ENR_FORMATION<2,i>)
  ENR_FORMEXPAIDANT=REPLACE(ENR_FORMEXPAIDANT,8,i;" ")          
 NEXT i

 NOUVCLESAL=EXTRACT(ENR_FIPAY,60)
 ENR_FORMEXPAIDANT<13>=""
 WRITE ENR_FORMEXPAIDANT ON F.FORMEXPAIDANT,NOUVCLESAL

REPEAT

DELETE F.VOC,"FIPAY"
DELETE F.VOC,"FORMATION"
DELETE F.VOC,"PARAM.FORM"

STOP

