***********************************************************
*
* TRANSPOSITION DU FICHIER DEM-ACCORD D'UN MODULE FACTURE
* VERS FICHIER DEMANDACC
*
* NOVEMBRE 1998                           DIDIER
***********************************************************
EXECUTE 'DATE.FORMAT'
PROCREAD VARIABLES ELSE STOP
MODULE=FIELD(VARIABLES," ",2)
OPEN "","VOC" TO F.VOC ELSE STOP
OPEN "","PARAMASSO" TO F.PARAMASSO ELSE STOP
READ ENRPARAMASSO FROM F.PARAMASSO,"1" ELSE STOP
TYPEBASE=EXTRACT(ENRPARAMASSO,6)
ENRVOC=""
ENRVOC=REPLACE(ENRVOC,1;"F")
CHEMIN="D:\TRANSFERT\":MODULE
IF TYPEBASE="P" THEN
 ENRVOC=REPLACE(ENRVOC,2;CHEMIN:"\DEM/ACCORD")
 ENRVOC=REPLACE(ENRVOC,3;CHEMIN:"\D_DEM/ACCORD")
 WRITE ENRVOC ON F.VOC,"DEM/ACCORD"
END ELSE
 ENRVOC=REPLACE(ENRVOC,2;CHEMIN:"\DEM-ACCORD")
 ENRVOC=REPLACE(ENRVOC,3;CHEMIN:"\D_DEM-ACCORD")
 WRITE ENRVOC ON F.VOC,"DEM-ACCORD"
END
ENRVOC=REPLACE(ENRVOC,2;CHEMIN:"\P.AIDEES")
ENRVOC=REPLACE(ENRVOC,3;CHEMIN:"\D_P.AIDEES")
WRITE ENRVOC ON F.VOC,"P.AIDEES"
ENRVOC=REPLACE(ENRVOC,2;CHEMIN:"\CAISSE")
ENRVOC=REPLACE(ENRVOC,3;CHEMIN:"\D_CAISSE")
WRITE ENRVOC ON F.VOC,"CAISSE"
IF TYPEBASE="P" THEN
 OPEN "","DEM/ACCORD" TO F.DEMACCORD ELSE STOP
END ELSE
 OPEN "","DEM-ACCORD" TO F.DEMACCORD ELSE STOP
END
OPEN "","P.AIDEES" TO F.PAIDEES ELSE STOP
OPEN "","DEMANDACC" TO F.DEMANDACC ELSE STOP
OPEN "","CAISSE" TO F.CAISSE ELSE STOP
CODEPB1=""
PASSAGE=0
*** TRAITEMENT
EXECUTE "TSELECT DEM-ACCORD PAR @ID PAR 3 PAR 4"
10 READNEXT CLEDEMACC ELSE
 IF PASSAGE=1 THEN WRITE ENRDEMANDACC ON F.DEMANDACC,CLECIVILAIDE
 DELETE F.VOC,"DEM-ACCORD"
 DELETE F.VOC,"DEM/ACCORD"
 DELETE F.VOC,"P.AIDEES"
 DELETE F.VOC,"CAISSE" 
 STOP
END
READ ENRDEMACCORD FROM F.DEMACCORD,CLEDEMACC ELSE GOTO 10
CODEPB=CLEDEMACC[1,4]
IF CODEPB1#CODEPB THEN
 IF CODEPB1#"" THEN WRITE ENRDEMANDACC ON F.DEMANDACC,CLECIVILAIDE
 ENRDEMANDACC=""
 CODEPB1=CODEPB
 READ ENRPAIDEES FROM F.PAIDEES,CODEPB ELSE ENRPAIDEES=""
 CLECIVILAIDE=EXTRACT(ENRPAIDEES,50)
END
CODECAISSE=EXTRACT(ENRDEMACCORD,1)
READ ENRCAISSE FROM F.CAISSE,CODECAISSE ELSE ENRCAISSE=""
CODEORGCHG=EXTRACT(ENRCAISSE,30)
DATEDEMACC=EXTRACT(ENRDEMACCORD,2)
DATEDEBDEMACC=EXTRACT(ENRDEMACCORD,3)
DATEFINDEMACC=EXTRACT(ENRDEMACCORD,4)
HEURESDEMACC=EXTRACT(ENRDEMACCORD,5)
ENRDEMANDACC=INSERT(ENRDEMANDACC,1,1,0;CODEORGCHG)
ENRDEMANDACC=INSERT(ENRDEMANDACC,2,1,0;DATEDEMACC)
ENRDEMANDACC=INSERT(ENRDEMANDACC,3,1,0;DATEDEBDEMACC)
ENRDEMANDACC=INSERT(ENRDEMANDACC,4,1,0;DATEFINDEMACC)
ENRDEMANDACC=INSERT(ENRDEMANDACC,5,1,0;HEURESDEMACC)
ENRDEMANDACC=INSERT(ENRDEMANDACC,6,1,0;"0")
PASSAGE=1
GOTO 10
