*********************************************************
*                                                    	*
*   Gnration du fichier DETAILCHGPARTEMP		*
*							*
* SEPTEMBRE 1999			Jrme RAVEAU   *
*							*
*********************************************************
	
	* CREATION VOC
	GOSUB 100

	*********************************************************
	* INITIALISATION DES VARIABLES				*
	*********************************************************
	W_REQVIDE = "FAUX"
	ENR_DECLARATION = ""
	ENR_EMPLOYEURS = ""
	ENR_DETAILCHGPARTEMP = ""
	W_NOUVEAUCODE=""
	W_TOTAL=0
	W_AN=0

	*********************************************************
	* OUVERTURE FICHIERS					*
	*********************************************************
	OPEN "","DECLARATION" TO F.DECLARATION ELSE STOP
	OPEN "","DETAILCHGPARTEMP" TO F.DETAILCHGPARTEMP ELSE STOP
	OPEN "","EMPLOYEURS" TO F.EMPLOYEURS ELSE STOP


	*********************************************************
	* DEBUT TRAITEMENT					*
	*********************************************************
	EXECUTE 'TSELECT DECLARATION'

	LOOP

		READNEXT CLEDECLAR ELSE W_REQVIDE="VRAI"
	UNTIL W_REQVIDE="VRAI" DO


		READ ENR_DECLARATION FROM F.DECLARATION,CLEDECLAR ELSE
			STOP
		END	
		

		*********************************************************
		* CREATION NOUVEAU CODE					*
		*********************************************************
		W_NOUVEAUCODE=""
		
		READ ENR_EMPLOYEURS FROM F.EMPLOYEURS,CLEDECLAR[1,4] THEN
			W_NOUVEAUCODE=ENR_EMPLOYEURS<50>
		
			*********************************************************
			* CONVERSION DATE					*
			*********************************************************
			IF CLEDECLAR[5,2] < 75 THEN
				W_AN="20":CLEDECLAR[5,2]		
			END ELSE
				W_AN="19":CLEDECLAR[5,2]
			END	
		
			*********************************************************
			* CUMUL ATTRIBUTS 1 A 6					*
			*********************************************************
			W_TOTAL=0
			FOR I=1 TO 6
				W_TOTAL=W_TOTAL+ENR_DECLARATION<I>
			NEXT I
			ENR_DETAILCHGPARTEMP=REPLACE(ENR_DETAILCHGPARTEMP,5;W_TOTAL/100)
			ENR_DETAILCHGPARTEMP=REPLACE(ENR_DETAILCHGPARTEMP,13;"")

			*********************************************************
			* ECRITURE						*
			*********************************************************
			WRITE ENR_DETAILCHGPARTEMP ON F.DETAILCHGPARTEMP,W_NOUVEAUCODE:W_AN:CLEDECLAR[7,1]

		END

	REPEAT
	
	* SUPPRESSION VOC
	GOSUB 200

	STOP


*************************************************************
* CREATION VOC                                              *
*************************************************************
100 *

	OPEN "","VOC" TO F.VOC ELSE STOP
	PROCREAD MODULE ELSE STOP
	W_MODULE=FIELD(MODULE," ",2)

	ENR_VOC=""
	ENR_VOC=REPLACE(ENR_VOC,1;"F")
	ENR_VOC=REPLACE(ENR_VOC,2;"D:\TRANSFERT\":W_MODULE:"\DECLARATION")
	ENR_VOC=REPLACE(ENR_VOC,3;"D:\TRANSFERT\":W_MODULE:"\D_DECLARATION")
	WRITE ENR_VOC ON F.VOC,"DECLARATION"

	ENR_VOC=""
	ENR_VOC=REPLACE(ENR_VOC,1;"F")
	ENR_VOC=REPLACE(ENR_VOC,2;"D:\TRANSFERT\":W_MODULE:"\EMPLOYEURS")
	ENR_VOC=REPLACE(ENR_VOC,3;"D:\TRANSFERT\":W_MODULE:"\D_EMPLOYEURS")
	WRITE ENR_VOC ON F.VOC,"EMPLOYEURS"

RETURN


*************************************************************
* SUPPRESSION VOC                                           *
*************************************************************
200 *
	DELETE F.VOC,"DECLARATION"
	DELETE F.VOC,"EMPLOYEURS"
RETURN