*******************************************************************************************************
*   PR de slection des FACTURORG sur l'organisme 000 (TAUX PRESTATION) en vue d'intgrer le nombre	*
* d'heures  taux plein  la stat 'Activit par organismes'...							*
*																	*
*******************************************************************************************************

EXECUTE "SET-THOUS ."
EXECUTE "DATE.FORMAT"
OPEN "", "TEMPO" TO F.TEMPO ELSE STOP
OPEN "", "FACTURORG" TO F.FACTURORG ELSE STOP
OPEN "", "STATACTAIDE" TO F.STATACTAIDE ELSE STOP
OPEN "", "CIVILAIDE" TO F.CIVILAIDE ELSE STOP
OPEN "", "ACTIVITES" TO F.ACTIVITES ELSE STOP
PROCREAD PARAMETRES ELSE STOP

W_Asso = FIELD(PARAMETRES,"|",2)
W_PeriodeDeb = FIELD(PARAMETRES,"|",3)
W_PeriodeFin = FIELD(PARAMETRES,"|",4)
W_Act = FIELD(PARAMETRES,"|",5)
W_ActSelect = FIELD(PARAMETRES,"|",6)
W_Tri = FIELD(PARAMETRES,"|",7)
W_TriSelect = FIELD(PARAMETRES,"|",8)
W_User = FIELD(PARAMETRES,"|",9)
W_TypeAide = FIELD(PARAMETRES,"|",10)
W_Date60 = FIELD(PARAMETRES,"|",11)

W_IncluAide = "F"

EXECUTE "SET-DEC ,"

W_Str = 'SELECT FACTURORG = "000]" AVEC PeriodeFacturOrg >= "':W_PeriodeDeb:'" AND AVEC PeriodeFacturOrg <= "':W_PeriodeFin:'"'

BEGIN CASE 
	CASE W_TypeAide="M"
		W_Str = W_Str:' AND AVEC NaissanceAide > "':W_Date60:'"'
	CASE W_TypeAide="P"
		W_Str = W_Str:' AND AVEC NaissanceAide <= "':W_Date60:'"'
END CASE

BEGIN CASE
	CASE W_Tri = "S"
		IF W_TriSelect # "" THEN
			W_Str = W_Str:' AND AVEC SecteurFacturOrg = "':W_TriSelect:']"'
		END ELSE
			W_Str = W_Str:' PAR LibSecteurFacturOrg'
		END
	CASE W_Tri = "R"
		IF W_TriSelect # "" THEN
			W_Str = W_Str:' AND AVEC ResponsableFacturOrg = "':W_TriSelect:'"'
		END ELSE
			W_Str = W_Str:' PAR NomRespFacturOrg'
		END
	CASE W_Tri = "C"
		IF W_TriSelect # "" THEN
			W_Str = W_Str:' AND AVEC CommuneFacturOrg = "':W_TriSelect:'"'
		END ELSE
			W_Str = W_Str:' PAR CommuneFacturOrg'
		END
	CASE 1
END CASE

W_Str = W_Str:' PAR CivilAideFacturOrg'


EXECUTE W_Str

ENR_TEMPO = ""
W_IndTempo = 1
W_NbDossier = 0
W_NbHeures = 0
W_TamponAide = ""
W_Fin = "F"

LOOP
	READNEXT W_Cle ELSE W_Fin = "V"
WHILE W_Fin = "F"

  IF W_Cle[5,5] # W_TamponAide THEN
	
	IF W_TamponAide # "" THEN
		 * Nb : on incrmente le nbre de dossier qu'aprs avoir parcouru les facturorg de l'aid !
		IF W_IncluAide = "V" THEN
			W_NbDossier = W_NbDossier + 1
		END
		
	END
	W_TamponAide = W_Cle[5,5]
	W_IncluAide = "F"
  END
 
  READ ENR_CIVILAIDE FROM F.CIVILAIDE, W_Cle[5,5] THEN
	
    BEGIN CASE
	CASE W_Tri = "S"
		IF W_TriSelect # ENR_CIVILAIDE<40>[1,3] THEN
			IF W_TriSelect # "" AND W_NbDossier # 0 THEN
				ENR_TEMPO<W_IndTempo,3>= W_NbDossier
				ENR_TEMPO<W_IndTempo,2>= W_NbHeures
				W_IndTempo = W_IndTempo + 1
			END
			W_TriSelect = ENR_CIVILAIDE<40>[1,3]
			ENR_TEMPO<W_IndTempo,1>= W_TriSelect
			W_NbDossier = 0
			W_NbHeures = 0
		END
	CASE W_Tri = "R"
		IF W_TriSelect # ENR_CIVILAIDE<39> THEN
			IF W_TriSelect # "" AND W_NbDossier # 0 THEN
				ENR_TEMPO<W_IndTempo,3>= W_NbDossier
				ENR_TEMPO<W_IndTempo,2>= W_NbHeures
				W_IndTempo = W_IndTempo + 1
			END
			W_TriSelect = ENR_CIVILAIDE<39>
			ENR_TEMPO<W_IndTempo,1>= W_TriSelect
			W_NbDossier = 0
			W_NbHeures = 0
		END
	CASE W_Tri = "C"
		IF W_TriSelect # ENR_CIVILAIDE<11> THEN
			IF W_TriSelect # "" AND W_NbDossier # 0 THEN
				ENR_TEMPO<W_IndTempo,3>= W_NbDossier
				ENR_TEMPO<W_IndTempo,2>= W_NbHeures
				W_IndTempo = W_IndTempo + 1
			END
			W_TriSelect = ENR_CIVILAIDE<11>
			ENR_TEMPO<W_IndTempo,1>= W_TriSelect
			W_NbDossier = 0
			W_NbHeures = 0
		END
	CASE 1
		* 
    END CASE

    W_IncluFacture = "F"
    GOSUB 100
    IF W_IncluFacture = "V" THEN	
	 READ ENR_FACTURORG FROM F.FACTURORG, W_Cle THEN
	   i = 0
	   LOOP
		i = i + 1
	   WHILE ENR_FACTURORG<1,i> # ""
		W_NbHeures = W_NbHeures + ENR_FACTURORG<1,i>
	   REPEAT	    
	   W_NbHeures = W_NbHeures + ENR_FACTURORG<5>
	 END
    END

  END
REPEAT

IF W_IncluAide = "V" THEN
	W_NbDossier = W_NbDossier + 1
END

IF W_NbDossier <> 0 THEN
	ENR_TEMPO<W_IndTempo,2> = W_NbHeures
	ENR_TEMPO<W_IndTempo,3> = W_NbDossier
END ELSE
	ENR_TEMPO = DELETE(ENR_TEMPO,W_IndTempo)
END
WRITE ENR_TEMPO ON F.TEMPO, "STATACTORGCHG":W_User

EXECUTE "SET-DEC ."

STOP

100
*************************************************
* Lecture STATACTAIDE pour dterminer si l'aid	*
* a eu une activit correspondant  la slection*
*************************************************
READ ENR_STATACTAIDE FROM F.STATACTAIDE, W_Cle[5,5]:W_Asso:W_Cle[13,6] THEN
	i = 0
	LOOP
		i = i + 1
	WHILE ENR_STATACTAIDE<1,i> # "" AND W_IncluFacture = "F"
		IF ENR_STATACTAIDE<1,i>[1,3] = W_Asso THEN
			READ ENR_ACTIVITES FROM F.ACTIVITES, ENR_STATACTAIDE<1,i> THEN
			  BEGIN CASE
				CASE W_Act = "R"
					IF W_ActSelect = ENR_ACTIVITES<17> THEN
						W_IncluFacture = "V"
						W_IncluAide = "V"
					END
				CASE W_Act = "S"
					IF W_ActSelect = ENR_ACTIVITES<13> THEN
						W_IncluFacture = "V"	
						W_IncluAide = "V"
					END
				CASE W_Act = "T"
					IF W_ActSelect = ENR_ACTIVITES<12> THEN
						W_IncluFacture = "V"	
						W_IncluAide = "V"
					END
				CASE 1
					IF W_ActSelect = ENR_STATACTAIDE<1,i> THEN
						W_IncluFacture = "V"	
						W_IncluAide = "V"
					END
	   		  END CASE			
			END
		END
	REPEAT
END
RETURN
