SUBROUTINE LISTEMOIDOMITIME(RETURNVAL,PARAMETRES,W_Sortie)
************************************************************
*                      ---DOMITIME---                      *
*                                                          *
* Ce programme liste les aidants qui ont entr des MOI.    *
*                                                          *
* Grgory - 28/11/2007                                     *
************************************************************
EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"

OPEN "","TLGPOINTAGE" TO F.TLGPOINTAGE ELSE STOP
OPEN "","TLGMOI" TO F.TLGMOI ELSE STOP
OPEN "","DOMITIME" TO F.DOMITIME ELSE STOP
OPEN "","CIVILAIDANT" TO F.CIVILAIDANT ELSE STOP
OPEN "","CIVILAIDE" TO F.CIVILAIDE ELSE STOP
OPEN "","SECTEUR" TO F.SECTEUR ELSE STOP
OPEN "","ACTIVITES" TO F.ACTIVITES ELSE STOP
OPEN "","TEMPO" TO F.TEMPO ELSE STOP
************************************************************

W_Date=DATE()

W_Annee=W_Date[7,4]
W_Mois=W_Date[4,2]
IF W_Mois="01" THEN
	W_Annee=W_Annee-1
	W_Mois="12"
END ELSE
	W_Temp=W_Annee:W_Mois
	W_Temp=W_Temp-1
	W_Mois=W_Temp[5,2]	
END

W_DateDeb=ICONV('01/':W_Mois:'/':W_Annee,'D4/')
W_DateFin=ICONV("01/":OCONV(W_DateDeb+32,"D4/")[4,7],"D4/")-1

W_HeureTrt=TIMEDATE()
W_HeureTrt=W_HeureTrt[1,2]:'H':W_HeureTrt[4,2]

ENR_TLGMOI=""
ENR_TLGPOINTAGE=""
ENR_DOMITIME=""
ENR_CIVILAIDANT=""
ENR_CIVILAIDE=""
ENR_SECTEUR=""
ENR_ACTIVITES=""
ENR_TEMPO=""

W_AncienAidant=""

W_Ind=0

W_Req=""

W_Ind=W_Ind+1
ENR_DOMITIME<W_Ind>="Secteur;Code aidant;Nom et prenom aidant;Code aide;Nom et prenom aide;Date;Rub. 11;Rub. 12;Rub. 21;Type act."

	EXECUTE 'SSELECT TLGMOI AVEC DateDebInterv >= "':W_DateDeb:'" AND <= "':W_DateFin:'" PAR CodeAidant PAR DateDebInterv'
	EXECUTE 'SAUVE-LISTE W_Req'
	EXECUTE "LISTE W_Req" RETURNING MSGCODE

	IF MSGCODE<1> # 209 THEN
		SELECT F.TLGMOI TO W_Req

		W_Fini="FAUX"
		LOOP
			READNEXT W_Cle FROM W_Req ELSE W_Fini="VRAI"
		WHILE W_Fini="FAUX" DO
			READ ENR_TLGMOI FROM F.TLGMOI, W_Cle THEN
				READ ENR_TLGPOINTAGE FROM F.TLGPOINTAGE, W_Cle ELSE ENR_TLGPOINTAGE=""
				READ ENR_CIVILAIDANT FROM F.CIVILAIDANT, W_Cle[3,5] ELSE ENR_CIVILAIDANT=""
				READ ENR_CIVILAIDE FROM F.CIVILAIDE, W_Cle[9,5] ELSE ENR_CIVILAIDE=""
				READ ENR_SECTEUR FROM F.SECTEUR, ENR_CIVILAIDANT<31> ELSE ENR_SECTEUR=""
				READ ENR_ACTIVITES FROM F.ACTIVITES, ENR_TLGPOINTAGE<5> ELSE ENR_ACTIVITES=""
			
				W_Ind=W_Ind+1
				ENR_DOMITIME<W_Ind>=ENR_SECTEUR<1>:';':W_Cle[3,5]:';':ENR_CIVILAIDANT<2>:' ':ENR_CIVILAIDANT<3>:';':W_Cle[9,5]:';':ENR_CIVILAIDE<2>:' ':ENR_CIVILAIDE<3>:';':OCONV(W_Cle[14,5],"D4/")
				
				W_Rub11=""
				W_Rub12=""
				W_Rub21=""
				FOR I=1 TO DCOUNT(ENR_TLGMOI<1>,CHAR(253))
					IF ENR_TLGMOI<1,I>="11" THEN
						W_Rub11=ENR_TLGMOI<2,I>
					END ELSE
						IF ENR_TLGMOI<1,I>="12" THEN
							W_Rub12=ENR_TLGMOI<2,I>
						END ELSE
							W_Rub21=ENR_TLGMOI<2,I>
						END
					END
				NEXT I
				
				ENR_DOMITIME<W_Ind>=ENR_DOMITIME<W_Ind>:';':W_Rub11:';':W_Rub12:';':W_Rub21:';':ENR_ACTIVITES<12>
			END
		REPEAT
	END
	
	ENR_TEMPO<1>=W_Ind-1
	WRITE ENR_TEMPO ON F.TEMPO, "LISTERMOIDOMITIME"
	
	WRITE ENR_DOMITIME ON F.DOMITIME, 'Liste des salaries ayant enregistr des MOI - ':OCONV(W_DateDeb,"D4-"):' au ':OCONV(W_DateFin,"D4-"):' ':W_HeureTrt:'.txt'
		
RETURN