*********************************************************
* Gnration du fichier CSV pour l'indicateur 6         *
*********************************************************
EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"
OPEN "","SECTEUR" TO F.SECTEUR ELSE STOP
OPEN "","CIVILAIDE" TO F.CIVILAIDE ELSE STOP
OPEN "","RESPONSABLE" TO F.RESPONSABLE ELSE STOP
OPEN "","STATAIDE" TO F.STATAIDE ELSE STOP
OPEN "","ACTIVITESBISAIDE" TO F.ACTIVITESBISAIDE ELSE STOP
*********************************************************

ENR_SECTEUR=""
ENR_CIVILAIDE=""
ENR_RESPONSABLE=""
ENR_STATAIDE=""
ENR_ACTBISAIDE=""

W_AncienCodeAide=""

W_ReqActAides=""

W_Ind=0

* Dclaration en dur
W_TypeAct="P"

*********************************************************

PRINT "Code association ?"
INPUT W_Asso

IF W_Asso = "" THEN STOP

PRINT "Date de debut (JJ/MM/AAAA)?"
INPUT W_DateDebExt

IF W_DateDebExt = "" THEN STOP

PRINT "Date de fin (JJ/MM/AAAA)?"
INPUT W_DateFinExt

IF W_DateFinExt = "" THEN STOP

W_DateDeb=ICONV(W_DateDebExt,"D4/")
W_DateFin=ICONV(W_DateFinExt,"D4/")

W_Ind=W_Ind+1
ENR_STATAIDE<W_Ind>="Code;Nom;Prenom;Secteur;Commune;Dept;Responsable;Age;Sexe;Date de naissance;Condition de vie"

	EXECUTE 'SELECT ACTIVITESBISAIDE AVEC CodeAssocBisAide = "':W_Asso:'" AND AVEC DateDebAct <= "':W_DateFin:'" AND AVEC 1 >= "':W_DateDeb:'" OR = "" AND AVEC TypeActBisAide = "':W_TypeAct:'" PAR NomPrenomBisAide PAR @ID'
	EXECUTE 'SAUVE-LISTE W_ReqActAides'
	EXECUTE "LISTE W_ReqActAides" RETURNING MSGCODE
	
	IF MSGCODE<1> # "209" THEN
		SELECT F.ACTIVITESBISAIDE TO W_ReqActAides

		W_Fin="FAUX"
		LOOP
			READNEXT W_Cle FROM W_ReqActAides ELSE W_Fin = "VRAI"
		WHILE W_Fin = "FAUX" DO
			IF W_AncienCodeAide="" THEN W_AncienCodeAide=W_Cle[1,5]
			IF W_AncienCodeAide<>W_Cle[1,5] THEN
				GOSUB 10
				W_AncienCodeAide=W_Cle[1,5]
			END
		REPEAT
		
		* On traite le dernier aide qui n'est pas pass dans la rupture.
		GOSUB 10
	END

	WRITE ENR_STATAIDE ON F.STATAIDE, "Indicateur de rpartition de la population - ":W_Asso:".txt"

STOP
**********************************************
10

	READ ENR_CIVILAIDE FROM F.CIVILAIDE, W_AncienCodeAide THEN
		READ ENR_SECTEUR FROM F.SECTEUR, ENR_CIVILAIDE<40>[1,3] ELSE ENR_SECTEUR=""
		READ ENR_RESPONSABLE FROM F.RESPONSABLE, ENR_CIVILAIDE<39> ELSE ENR_RESPONSABLE=""
		
		W_Age=""
		W_Sexe=""
		W_CondVie=""
		
		IF ENR_CIVILAIDE<20><>"" THEN
			W_Age=INT((W_DateFin-ENR_CIVILAIDE<20>)/365)
		END
		
		IF ENR_CIVILAIDE<17>="M" THEN W_Sexe="H"
		IF ENR_CIVILAIDE<17>="F" THEN W_Sexe="F"
		
		W_Conjoint="NON"
		W_Enfant="NON"
		W_FrereSoeur="NON"
		W_Parent="NON"
		W_Autre="NON"
		
		IF ENR_CIVILAIDE<26><>"" THEN
			IF ENR_CIVILAIDE<31><>"3" AND ENR_CIVILAIDE<31><>"4" THEN W_Conjoint="OUI"
		END
		
		I=0
		LOOP
			I=I+1
		WHILE ENR_CIVILAIDE<37,I><>"" DO
			BEGIN CASE
				CASE ENR_CIVILAIDE<37,I>="Petit enfant" OR ENR_CIVILAIDE<37,I>="Enfant"
					W_Enfant="OUI"
				CASE ENR_CIVILAIDE<37,I>[10,5]="soeur"
					W_FrereSoeur="OUI"
				CASE ENR_CIVILAIDE<37,I>="Parent" OR ENR_CIVILAIDE<37,I>="Grand-parent"
					W_Parent="OUI"
				CASE ENR_CIVILAIDE<37,I>="Autre"
					W_Autre="OUI"
			END CASE
		REPEAT
		
		IF W_Conjoint="NON" AND W_Enfant="NON" AND W_Parent="NON" AND W_Autre="NON" AND W_FrereSoeur="NON" THEN
			W_CondVie="SEUL"
		END ELSE
			IF W_Enfant="OUI" THEN
				W_CondVie="GENERATION SUIVANTE"
			END ELSE
				IF W_Conjoint="OUI" OR W_FrereSoeur="OUI" OR W_Autre="OUI" THEN
					W_CondVie="COUPLE OU MEME GENERATION"
				END ELSE
					IF W_Parent="OUI" THEN
						W_CondVie="GENERATION PRECEDENTE"
					END ELSE
						W_CondVie="SEUL"
					END
				END
			END
		END
		
		W_Ind=W_Ind+1
		ENR_STATAIDE<W_Ind>=W_AncienCodeAide:';':ENR_CIVILAIDE<2>:';':ENR_CIVILAIDE<3>:';':ENR_SECTEUR<1>:';':ENR_CIVILAIDE<11>:';':ENR_CIVILAIDE<10>[1,2]:';':ENR_RESPONSABLE<1>:';':W_Age:';':W_Sexe:';':OCONV(ENR_CIVILAIDE<20>,"D4/"):';':W_CondVie
	END ELSE
		PRINT "Cle - ":W_Cle
	END
RETURN