*********************************************************
* Gnration du fichier CSV pour l'indicateur 6         *
*********************************************************
EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"
OPEN "","CONTRAT" TO F.CONTRAT ELSE STOP
OPEN "","SECTEUR" TO F.SECTEUR ELSE STOP
OPEN "","CIVILAIDANT" TO F.CIVILAIDANT ELSE STOP
OPEN "","GRILLESCC" TO F.GRILLESCC ELSE STOP
OPEN "","DETAILCALCUL" TO F.DETAILCALCUL ELSE STOP
OPEN "","STATAIDANT" TO F.STATAIDANT ELSE STOP
OPEN "","FORMEXPAIDANT" TO F.FORMEXPAIDANT ELSE STOP
OPEN "","TABLES" TO F.TABLES ELSE STOP
*********************************************************

ENR_CONTRAT=""
ENR_SECTEUR=""
ENR_CIVILAIDANT=""
ENR_GRILLESCC=""
ENR_DETAILCALCUL=""
ENR_STATAIDANT=""
ENR_FORMEXPAIDANT=""
ENR_TABLES=""

W_ReqContrat=""

W_Ind=0

W_CodeGrille=""
W_PalierGrille=""
W_QualifPro=""
W_Coef=""
W_Avenant=""
W_Lib=""
W_HrsContrat=""

PRINT "Code association ?"
INPUT W_Asso

IF W_Asso = "" THEN STOP

PRINT "Date d'arret (JJ/MM/AAAA)?"
INPUT W_DateArretExt

IF W_DateArretExt = "" THEN STOP

W_Periode=W_DateArretExt[7,4]:W_DateArretExt[4,2]
W_DateArret=ICONV(W_DateArretExt,"D4/")

W_Ind=W_Ind+1
ENR_STATAIDANT<W_Ind>="Code;Nom;Prenom;Qualification;Secteur;Dept;Indice base;Grille;Indice poste occupe;Nb heures;Nb heures contrat;Dip. ou niv.;Formation;Specialite;Niveau"

	READ ENR_TABLES FROM F.TABLES, "DIPLOMES" ELSE ENR_TABLES=""


	EXECUTE 'SELECT CONTRAT AVEC 2 = "':W_Asso:'" AND AVEC 1 <> "02" AND AVEC 65 = "" AND AVEC 7 <= "':W_DateArret:'" AND AVEC 8 >= "':W_DateArret:'" OR = "" PAR 20 PAR CodeAidant'
	EXECUTE 'SAUVE-LISTE W_ReqContrat'
	EXECUTE "LISTE W_ReqContrat" RETURNING MSGCODE
	
	IF MSGCODE<1> # "209" THEN
		SELECT F.CONTRAT TO W_ReqContrat

		W_Fin="FAUX"
		LOOP
			READNEXT W_CleContrat FROM W_ReqContrat ELSE W_Fin = "VRAI"
		WHILE W_Fin = "FAUX" DO
			W_CodeGrille=""
			W_PalierGrille=""
			W_QualifPro=""
			W_Coef=""
			W_Avenant=""
			READ ENR_CONTRAT FROM F.CONTRAT, W_CleContrat THEN
				READ ENR_CIVILAIDANT FROM F.CIVILAIDANT, W_CleContrat[1,5] THEN
					W_Sortir="FAUX"
					I=DCOUNT(ENR_CONTRAT<15>, CHAR(253))+1
					LOOP
						I=I-1
					WHILE W_Sortir="FAUX" AND I>0 DO
						IF ENR_CONTRAT<15,I><=W_DateArret THEN
							W_CodeGrille=ENR_CONTRAT<20,I>
							W_QualifPro=ENR_CONTRAT<16,I>
							BEGIN CASE
								CASE ENR_CONTRAT<25,I>="1"
									W_HrsContrat=INT((ENR_CONTRAT<24,I>*52)/12)
								CASE ENR_CONTRAT<25,I>="2"
									W_HrsContrat=INT((ENR_CONTRAT<24,I>*26)/12)
								CASE ENR_CONTRAT<25,I>="3"
									W_HrsContrat=ENR_CONTRAT<24,I>
								CASE ENR_CONTRAT<25,I>="4"
									W_HrsContrat=INT(ENR_CONTRAT<24,I>/12)
							END CASE
							W_Avenant=I
							W_Sortir="VRAI"
						END
					REPEAT
					
					IF W_CodeGrille<>"" THEN
						READ ENR_SECTEUR FROM F.SECTEUR, ENR_CIVILAIDANT<31> ELSE ENR_SECTEUR=""
						READ ENR_GRILLESCC FROM F.GRILLESCC, W_CodeGrille ELSE ENR_GRILLESCC=""
						READ ENR_DETAILCALCUL FROM F.DETAILCALCUL, W_CleContrat:W_Periode ELSE ENR_DETAILCALCUL=""
						READ ENR_FORMEXPAIDANT FROM F.FORMEXPAIDANT, W_CleContrat[1,5] ELSE ENR_FORMEXPAIDANT=""
						
						W_Params=""
						W_Params<1>=W_CleContrat
						W_Params<2>=W_Avenant
						W_Params<3>=W_Periode
						CALL CALCCOEFFTXHOR("",W_Params,W_Sortie)
						W_Coef=W_Sortie<1>
						
						J=0
						W_SortirTable="FAUX"
						LOOP
							J=J+1
						WHILE ENR_TABLES<2,J>#"" AND W_SortirTable="FAUX" DO
							IF ENR_TABLES<2,J>=ENR_FORMEXPAIDANT<2> THEN
								J=J-1
								W_SortirTable="VRAI"
							END
						REPEAT
						
						W_Lib=""
						W_Niv=ENR_TABLES<4,J>
						IF ENR_FORMEXPAIDANT<1>="N" THEN
							W_Lib="Niveau"
							IF W_Niv<6 THEN
								W_Niv=ENR_TABLES<4,J>+1
							END
						END ELSE
							W_Lib="Diplome"
						END
						
						W_Ind=W_Ind+1
						ENR_STATAIDANT<W_Ind>=W_CleContrat[1,5]:';':ENR_CIVILAIDANT<2>:';':ENR_CIVILAIDANT<3>:';':W_QualifPro:';':ENR_SECTEUR<1>:';':ENR_CIVILAIDANT<10>[1,2]:';':ENR_GRILLESCC<4,1> "MR3,":';':ENR_GRILLESCC<1>:';':W_Coef "MR3,":';':ENR_DETAILCALCUL<6> "MR2,":';':W_HrsContrat "MR2,":';':W_Lib:';':ENR_TABLES<3,J>:';':ENR_FORMEXPAIDANT<4>:';':W_Niv
					END
				END
			END
		REPEAT
	END

	WRITE ENR_STATAIDANT ON F.STATAIDANT, "Indicateur de vieillesse technicite - ":W_Asso:".txt"

STOP