********************************************************
* REMPLI L'ENREGISTREMENT EDCOMPLFACT DE TEMPO QUI     *
* CONTIENT L'IMPRESSION DES COMPLEMENTS DE FACTURATION *
* 02/07/2001 ALAIN                                     *
* 02/04/2002 Grgory                                   *
********************************************************

***************************
* Ouvertures des fichiers *
***************************
EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"
OPEN "","CIVILAIDE" TO F.CIVILAIDE ELSE STOP
OPEN "","COMMUNES" TO F.COMMUNES ELSE STOP
OPEN "","COMPLFACT" TO F.COMPLFACT ELSE STOP
OPEN "","RESPONSABLE" TO F.RESPONSABLE ELSE STOP
OPEN "","SECTEUR" TO F.SECTEUR ELSE STOP
OPEN "","TEMPO" TO F.TEMPO ELSE STOP

******************************
* Recuperation des arguments *
******************************
PROCREAD ARGUMENTS ELSE PRINT "Procread"

W_ASSOC=FIELD(ARGUMENTS,"|",2)
W_CODEACTIVITE=FIELD(ARGUMENTS,"|",3)
W_CODESELECTION=FIELD(ARGUMENTS,"|",4)
W_TYPESELECTION=FIELD(ARGUMENTS,"|",5)

*********************
* TRAITEMENT GLOBAL *
*********************

W_VERIF = ""
W_SELECTION = ""
ATT = ""
TOT = 'TOTAL :'

IF W_CODESELECTION = "" THEN
	IF W_TYPESELECTION = "R" THEN
		W_SELECTION = 'PAR LibRespAide '
		ATT = 39
		TOT = 'TOTAL RESPONSABLE : '
	END ELSE
		IF W_TYPESELECTION = "S" THEN
			W_SELECTION = 'PAR LibSecteurAide '
			ATT = 40
			TOT = 'TOTAL SECTEUR : '
		END ELSE
			IF W_TYPESELECTION = "C" THEN
				W_SELECTION = 'PAR LibelleCommuneAide '
				ATT = 11
				TOT = 'TOTAL COMMUNE : '
			END
		END
	END
END ELSE
	IF W_TYPESELECTION = "R" THEN
		W_SELECTION = 'AND AVEC ResponsableAide = "':W_CODESELECTION:'" '
		ATT = 39
		TOT = 'TOTAL RESPONSABLE : '
	END ELSE
		IF W_TYPESELECTION = "S" THEN
			W_SELECTION = 'AND AVEC CodeSecteur = "':W_CODESELECTION:'" '
			ATT = 40
			TOT = 'TOTAL SECTEUR : '
		END ELSE
			IF W_TYPESELECTION = "C" THEN
				READ ENR_SELECT FROM F.COMMUNES ,W_CODESELECTION ELSE ENR_SELECT = ""
				W_SELECTION = 'AND AVEC LibelleCommuneAide = "':ENR_SELECT<1>:'" '
				ATT = 11
				TOT = 'TOTAL COMMUNE : '
			END
		END
	END
END

W_SELECTION = W_SELECTION:'PAR NomAideComplFact PAR PrenomAideComplFact'
W_VERIF = 'SSELECT COMPLFACT AVEC CodAssocComplFact = "':W_ASSOC:'" ':W_SELECTION
PRINT W_VERIF
IF W_CODEACTIVITE = "T" THEN
	EXECUTE 'SSELECT COMPLFACT AVEC CodAssocComplFact = "':W_ASSOC:'" ':W_SELECTION
END ELSE
	EXECUTE 'SSELECT COMPLFACT AVEC CodAssocComplFact = "':W_ASSOC:'" AND AVEC @ID = "[':W_CODEACTIVITE:'" ':W_SELECTION
END

EXECUTE 'SAUVE-LISTE W_RESULTAT' 
EXECUTE "LISTE W_RESULTAT" RETURNING MSGCODE

IF MSGCODE<1> # 209 THEN

	SELECT F.COMPLFACT TO W_RESULTAT

	W_FINI = "FAUX"
	ENR_SELECT = ""
	ENR_TEMPO = ""	
	ANCSELECT = ""
	SELECT = ""
	CUMUL = 0
	CUMULTOT = 0
	I = 0

	LOOP
		READNEXT CLE.COMPLFACT FROM W_RESULTAT ELSE W_FINI = "VRAI"
	WHILE W_FINI = "FAUX"
		W_AIDE = CLE.COMPLFACT[1,5]
		READ ENR_COMPLFACT FROM F.COMPLFACT ,CLE.COMPLFACT ELSE ENR_COMPLFACT = ""
		READ ENR_CIVILAIDE FROM F.CIVILAIDE,W_AIDE ELSE ENR_CIVILAIDE = ""			
		
		IF ATT # "" THEN
			SELECT = ENR_CIVILAIDE<ATT>
		END
		
		IF ATT = 40 THEN
			SELECT = SELECT[1,3]
		END		
	
		IF ANCSELECT # SELECT THEN
			I = I + 1

			IF ANCSELECT # "" THEN
				CUMULTOT = CUMULTOT + CUMUL
				CUMUL = CUMUL / 100
				CUMUL = CUMUL "R2"
				CUMUL = CUMUL "R(#12)"
				ENR_TEMPO<I,3> = TOT:CUMUL
				CUMUL = 0
			END

			ANCSELECT = SELECT
			
			IF ATT # "" THEN

				IF ATT = 39 THEN
					READ ENR_SELECT FROM F.RESPONSABLE ,SELECT ELSE ENR_SELECT = ""
					IMP = 'Responsable      : '
				END ELSE
					IF ATT = 11 THEN
						ENR_SELECT<1> = SELECT
						IMP = 'Commune          : '
					END ELSE
						IF ATT = 40 THEN
							READ ENR_SELECT FROM F.SECTEUR ,SELECT[1,3] ELSE ENR_SELECT = ""
							IMP = 'Secteur          : '
						END ELSE
							ENR_SELECT = ""
						END
					END
				END

				IMP = IMP:ENR_SELECT<1>

				ENR_TEMPO<I,1> = 'STPAGE'
				ENR_TEMPO<I,2> = IMP

			END

		END

		J = 0
		LOOP
			J = J + 1
		WHILE ENR_COMPLFACT<1,J> # "" DO
			I = I + 1
			IF J = 1 THEN
				AIDE = ENR_CIVILAIDE<2>:' ':ENR_CIVILAIDE<3>
				AIDE = AIDE[1,35]
				IMP = SPACE(1):W_AIDE:SPACE(1):AIDE:SPACE(37 - LEN(AIDE))
			END ELSE
				IMP = SPACE(44)
			END

			IMP = IMP:CLE.COMPLFACT[9,1]:SPACE(3)

			LIB = ENR_COMPLFACT<1, J>[1,35]
			IMP = IMP:LIB:SPACE(35 - LEN(LIB))

			IF ENR_COMPLFACT<2,J> # "" THEN
				MONTANT = ENR_COMPLFACT<2,J> / 100
				MONTANT = MONTANT "R2"
				MONTANT = MONTANT "R(#10)"
				IMP = IMP:MONTANT
			END ELSE
				IMP = IMP:SPACE(10)
			END

			IF ENR_COMPLFACT<3,J> # "" THEN
				MONTANT = ENR_COMPLFACT<3,J> / 100
				MONTANT = MONTANT "R2"
				MONTANT = MONTANT "R(#10)"
				IMP = IMP:MONTANT
			END ELSE
				IMP = IMP:SPACE(10)
			END

			MONTANT = ENR_COMPLFACT<4,J> / 100
			MONTANT = MONTANT "R2"
			MONTANT = MONTANT "R(#10)"
			IMP = IMP:MONTANT

			CUMUL = CUMUL + ENR_COMPLFACT<4,J>

			CPTE = ENR_COMPLFACT<5,J> "R(#10)"
			IMP = IMP:SPACE(1):CPTE
			
			
			IF ENR_COMPLFACT<6,J> # "" THEN
				IMP = IMP:SPACE(3):ENR_COMPLFACT<6,J>
			END

			ENR_TEMPO<I,1> = IMP
			ENR_TEMPO<I,2> = SELECT
			ENR_TEMPO<I,3> = MONTANT

		REPEAT

	REPEAT
END ELSE
	ENR_TEMPO<1,1> = "NEANT"
END

IF CUMULTOT # "" THEN
	I = I + 1
	CUMULTOT = CUMULTOT + CUMUL
	CUMUL = CUMUL / 100
	CUMUL = CUMUL "R2"
	CUMUL = CUMUL "R(#12)"
	ENR_TEMPO<I,1> = IMP
	ENR_TEMPO<I,2> = SELECT
	ENR_TEMPO<I,3> = TOT:CUMUL
	CUMULTOT = CUMULTOT / 100
	CUMULTOT =  CUMULTOT "R2"
	CUMULTOT = CUMULTOT "R(#12)"
	ENR_TEMPO<I,1> = 'TOTAL GENERAL : ':CUMULTOT
END

WRITE ENR_TEMPO TO F.TEMPO,"EDCOMPLFACT"

EXECUTE 'EFFACER-LISTE W_RESULTAT'

STOP
