*************************************************************************
*
*   EDITION DES ETATS DE PRESENCE DOMICILE SERVICE
*
*   VANESSA
*   19/01/2001                                       
*************************************************************************

* OUVERTURE DES FICHIERS

EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"
OPEN "","CIVILAIDANT" TO F.CIVILAIDANT ELSE PRINT "OUVERTURE CIVILAIDANT"
OPEN "","CIVILAIDE" TO F.CIVILAIDE ELSE PRINT "OUVERTURE CIVILAIDE"
OPEN "","DETAILPREST" TO F.DETAILPREST ELSE PRINT "OUVERTURE DETAILPREST"
OPEN "","PERIODESPAIE" TO F.PERIODESPAIE ELSE PRINT "OUVERTURE PERIODESPAIE"

*************************************************************************


   EXECUTE 'SETPTR 0,,,,,1, "MODE=RAW",DEST \\SERVEURVIEUX\HP5SINX,NOHEAD,NOFMT,EJECT,COPIES 1,BRIEF'

   PRINTER ON

   READ ENR_PERIODESPAIE FROM F.PERIODESPAIE,"1" ELSE ENR_PERIODESPAIE = ""

   EXECUTE 'SSELECT DETAILPREST AVEC PeriodeDetailPrest = "':ENR_PERIODESPAIE<1>:'" PAR NomAidantDetailPrest'

   EXECUTE 'SAUVE-LISTE W_RequetePres'
   EXECUTE "LISTE W_RequetePres" RETURNING MSGCODE

   IF MSGCODE<1> = "209" THEN
      STOP
   END ELSE
      SELECT F.DETAILPREST TO W_RequetePres
      W_Fini="FAUX"
      LOOP
         READNEXT W_ClePres FROM W_RequetePres ELSE W_Fini="VRAI"
      WHILE W_Fini="FAUX" DO
         READ ENR_DETAILPREST FROM F.DETAILPREST,W_ClePres ELSE ENR_DETAILPREST = ""

         READ ENR_CIVILAIDANT FROM F.CIVILAIDANT,W_ClePres[1,5] ELSE ENR_CIVILAIDANT = ""
         W_AdrAidant=""
         W_NomAidant=""
         W_LieuAidant=""
         W_VilleAidant=""

         W_NomAidant=ENR_CIVILAIDANT<2>:" ":ENR_CIVILAIDANT<3>

         IF ENR_CIVILAIDANT<5> # "" THEN W_AdrAidant=ENR_CIVILAIDANT<5>:" "
         IF ENR_CIVILAIDANT<6> # "" THEN W_AdrAidant=W_AdrAidant:ENR_CIVILAIDANT<6>:" "
         IF ENR_CIVILAIDANT<7> # "" THEN W_AdrAidant=W_AdrAidant:ENR_CIVILAIDANT<7>:" "
         IF ENR_CIVILAIDANT<8> # "" THEN W_AdrAidant=W_AdrAidant:ENR_CIVILAIDANT<8>
         IF ENR_CIVILAIDANT<9> # "" THEN W_LieuAidant=ENR_CIVILAIDANT<9>

         W_VilleAidant=ENR_CIVILAIDANT<10>:" ":ENR_CIVILAIDANT<11>

         W_Count=DCOUNT(ENR_DETAILPREST<1>,CHAR(253))

         FOR i = 1 TO W_Count

            READ ENR_CIVILAIDE FROM F.CIVILAIDE,ENR_DETAILPREST<1,i> ELSE ENR_CIVILAIDE = ""  

            W_AdrAide=""
            W_NomAide=""
            W_LieuAide=""
            W_VilleAide=""

            W_NomAide=ENR_CIVILAIDE<2>:" ":ENR_CIVILAIDE<3>

            IF ENR_CIVILAIDE<5> # "" THEN W_AdrAide=ENR_CIVILAIDE<5>:" "
            IF ENR_CIVILAIDE<6> # "" THEN W_AdrAide=W_AdrAide:ENR_CIVILAIDE<6>:" "
            IF ENR_CIVILAIDE<7> # "" THEN W_AdrAide=W_AdrAide:ENR_CIVILAIDE<7>:" "
            IF ENR_CIVILAIDE<8> # "" THEN W_AdrAide=W_AdrAide:ENR_CIVILAIDE<8>
            IF ENR_CIVILAIDE<9> # "" THEN W_LieuAide=ENR_CIVILAIDE<9>

            W_VilleAide=ENR_CIVILAIDE<10>:" ":ENR_CIVILAIDE<11>

            PRINT 
            PRINT 
            PRINT
            PRINT "                                        BENEFICIAIRE :   ":ENR_DETAILPREST<1,i>
            PRINT "                                             ":W_NomAide
            PRINT "                                             ":W_AdrAide
            PRINT "                                             ":W_LieuAide
            PRINT "                                             ":W_VilleAide
            PRINT 
            PRINT "                                        SALARIE      :   ":W_ClePres[1,5]
            PRINT "                                             ":W_NomAidant
            PRINT "                                             ":W_AdrAidant
            PRINT "                                             ":W_LieuAidant
            PRINT "                                             ":W_VilleAidant
            PAGE

         NEXT i

      REPEAT
   END

   PRINTER OFF
   PRINTER CLOSE

STOP
