**********************************************************
*  PREPARATION A L'EDITION DES ETIQUETTES SUR IMPRIMANTE
*  MATRICIELLE
*  Vanessa
*  OCTOBRE 2002
**********************************************************

* Ouvertures des fichiers

EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"
OPEN "","CIVILAIDANT" TO F.CIVILAIDANT ELSE PRINT "OUVERTURE CIVILAIDANT" ;* en lecture
OPEN "","CIVILAIDE" TO F.CIVILAIDE ELSE PRINT "OUVERTURE CIVILAIDE" ;* en lecture 
OPEN "","ELTSFACTAIDE" TO F.ELTSFACTAIDE ELSE PRINT "OUVERTURE ELTSFACTAIDE" ;* en lecture 
OPEN "","ETIQUETTE" TO F.ETIQUETTE ELSE PRINT "OUVERTURE ETIQUETTE" ;* en lecture criture
OPEN "","SAVEDLISTS" TO F.SAVEDLISTS ELSE PRINT "OUVERTURE SAVEDLISTS" ;* en lecture
*********************************************************
* initialisation des variables

ENR_ETIQUETTE=""
W_NumOrdre=1
W_Temp=""
W_AncienCode=""
W_Debut=0
W_Fin=0
W_Len=0
*********************************************************
*  Rcupration des arguments

PROCREAD ARGUMENTS ELSE STOP
W_User=FIELD(ARGUMENTS," ",2)
W_Param=FIELD(ARGUMENTS," ",3)
W_SauveImpr=FIELD(ARGUMENTS," ",4)
*********************************************************
*  PROGRAMME PRINCIPAL

   EXECUTE 'TSELECT SAVEDLISTS AVEC @ID = "ETIQ':W_User:']"'
   EXECUTE 'SAUVE-LISTE W_RequeteEtiq'
   EXECUTE "LISTE W_RequeteEtiq" RETURNING MSGCODE

   IF MSGCODE<1> # 209 THEN

      SELECT F.SAVEDLISTS TO W_RequeteEtiq

      W_Fin="FAUX"

      LOOP
         READNEXT W_Cle FROM W_RequeteEtiq ELSE W_Fin = "VRAI"
      WHILE W_Fin = "FAUX" DO
         READ ENR_SAVEDLISTS FROM F.SAVEDLISTS,W_Cle ELSE ENR_SAVEDLISTS=""
         W_Count=DCOUNT(ENR_SAVEDLISTS,CHAR(254))

         FOR j=1 TO W_Count

            IF W_AncienCode # ENR_SAVEDLISTS<j>[1,5] THEN

               ENR_ETIQUETTE=""
               ENR_ETIQUETTE<1>=W_User

               BEGIN CASE
                  CASE W_Param="AIDANT"
                     READ ENR_COORDONNEES FROM F.CIVILAIDANT,ENR_SAVEDLISTS<j>[1,5] ELSE ENR_COORDONNEES=""
                     i=5
                  CASE W_Param="AIDE"
                     READ ENR_COORDONNEES FROM F.CIVILAIDE,ENR_SAVEDLISTS<j>[1,5] ELSE ENR_COORDONNEES=""
                     i=5
                  CASE W_Param="ADRFACT"
                     READ ENR_COORDONNEES FROM F.ELTSFACTAIDE,ENR_SAVEDLISTS<j>[1,5] ELSE ENR_COORDONNEES=""
                     i=3
               END CASE

               * titre + nom + prnom
               IF i=5 THEN
                  ENR_ETIQUETTE<2>=ENR_COORDONNEES<1>:" ":ENR_COORDONNEES<2>:" ":ENR_COORDONNEES<3>
               END ELSE
                  ENR_ETIQUETTE<2>=ENR_COORDONNEES<2>
               END

               * adresse
               IF ENR_COORDONNEES<i> # "" AND ENR_COORDONNEES<i> # " " THEN
                  ENR_ETIQUETTE<3> = ENR_COORDONNEES<i>:" "
               END
               IF ENR_COORDONNEES<i+1> <> "" AND ENR_COORDONNEES<i+1> <> " " THEN
                  ENR_ETIQUETTE<3> = ENR_ETIQUETTE<3>:ENR_COORDONNEES<i+1>:" "
               END
               IF ENR_COORDONNEES<i+2> <> "" AND ENR_COORDONNEES<i+2> <> " " THEN
                  ENR_ETIQUETTE<3> = ENR_ETIQUETTE<3>:ENR_COORDONNEES<i+2>:" "
               END
               ENR_ETIQUETTE<3> = ENR_ETIQUETTE<3>:ENR_COORDONNEES<i+3>

               * complment d'adresse
               IF ENR_COORDONNEES<i+4> # "" AND ENR_COORDONNEES<i+4> # " " THEN
                  IF ENR_ETIQUETTE<3>="" THEN
                     ENR_ETIQUETTE<3> = ENR_COORDONNEES<i+4>
                  END ELSE
                     ENR_ETIQUETTE<4> = ENR_COORDONNEES<i+4>
                  END
               END

               * code postal + ville
               IF ENR_ETIQUETTE<3>="" THEN
                  ENR_ETIQUETTE<3> = ENR_COORDONNEES<i+5>:" ":ENR_COORDONNEES<i+6>
               END ELSE
                  IF ENR_ETIQUETTE<4>=""  THEN
                     ENR_ETIQUETTE<4> = ENR_COORDONNEES<i+5>:" ":ENR_COORDONNEES<i+6>
                  END ELSE
                     ENR_ETIQUETTE<5> = ENR_COORDONNEES<i+5>:" ":ENR_COORDONNEES<i+6>
                  END
               END

               WRITE ENR_ETIQUETTE ON F.ETIQUETTE,W_User:W_NumOrdre "R%5"
               W_NumOrdre=W_NumOrdre+1
         
               W_AncienCode = ENR_SAVEDLISTS<j>[1,5]
            END

         NEXT j
      REPEAT

      W_Temp='SETPTR 0,,,0,0,1,"MODE=RAW",DEST ':W_SauveImpr:',NOHEAD,NOFMT,NOEJECT,COPIES 1,BRIEF'

      EXECUTE W_Temp

   END

STOP
