EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"
OPEN "","DETAILCALCUL" TO F.DETAILCALCUL ELSE STOP
OPEN "","CONTRAT" TO F.CONTRAT ELSE STOP
OPEN "","CIVILAIDANT" TO F.CIVILAIDANT ELSE STOP
OPEN "","SECTEUR" TO F.SECTEUR ELSE STOP

PRINT "PERIODE : "
INPUT PERIODE
EXECUTE 'SELECT DETAILCALCUL AVEC TypeContrat = "D" AND AVEC TypeHeure = "H" AND AVEC @ID = "[':PERIODE:'" AND AVEC ConvColContratDetailCalcul = "01" PAR LibSectAidant PAR NomAidantDetailCalcul PAR PrenomAidantDetailCalcul'
PRINTER ON
PRINT "Code    Secteur Aidant       Nom Aidant           Prenom Aidant        Cont.+10   Reel"
PRINT

W_Fini="FAUX"
LOOP
   READNEXT W_Cle ELSE W_Fini="VRAI"
WHILE W_Fini="FAUX" DO
   READ ENR_DETAILCALCUL FROM F.DETAILCALCUL,W_Cle ELSE STOP
   READ ENR_CONTRAT FROM F.CONTRAT,W_Cle[1,8] ELSE STOP

W_Date=ICONV("01/":PERIODE[5,2]:"/":PERIODE[1,4],"D4/")

   i=DCOUNT(ENR_CONTRAT<15>,CHAR(253))
   LOOP
   WHILE W_Date < ENR_CONTRAT<15,i> DO
      i=i-1
   REPEAT

   W_Freq=ENR_CONTRAT<25,i>

   BEGIN CASE
      CASE W_Freq="1"
         W_Duree=INT(ENR_CONTRAT<24,i> * 52 / 12 + 1/2)
      CASE W_Freq="2"
         W_Duree=INT(ENR_CONTRAT<24,i> * 26 / 12 + 1/2)
      CASE W_Freq="3"
         W_Duree=ENR_CONTRAT<24,i>
      CASE W_Freq="4"
         W_Duree=INT(ENR_CONTRAT<24,i> / 12 + 1/2)
   END CASE

   W_Duree10=INT(W_Duree * 1.1 + 1/2)

   IF ENR_DETAILCALCUL<6> > W_Duree10 THEN
      READ ENR_CIVILAIDANT FROM F.CIVILAIDANT,W_Cle[1,5] ELSE STOP
      READ ENR_SECTEUR FROM F.SECTEUR,ENR_CIVILAIDANT<31> ELSE STOP

      W_Secteur=ENR_SECTEUR<1>
      W_Secteur=W_Secteur[1,20]
      W_Secteur=W_Secteur:SPACE(21 - LEN(W_Secteur))

      W_Nom=ENR_CIVILAIDANT<2>
      W_Nom=W_Nom[1,20]
      W_Nom=W_Nom:SPACE(21 - LEN(W_Nom))

      W_Prenom=ENR_CIVILAIDANT<3>
      W_Prenom=W_Prenom[1,20]
      W_Prenom=W_Prenom:SPACE(21 - LEN(W_Prenom))

      W_Duree10=W_Duree10/100
      W_Duree10=SPACE(6 - LEN(W_Duree10)):W_Duree10

      W_Reel=ENR_DETAILCALCUL<6>/100
      W_Reel=SPACE(6 - LEN(W_Reel)):W_Reel     

      PRINT W_Cle[1,5]:"   ":W_Secteur:W_Nom:W_Prenom:" ":W_Duree10:"   ":W_Reel
   END

REPEAT

STOP
