**********************************************************
*  gnrer un fichier texte de base de donnes Word
*  Programme chaine  partir d'un projet VB
*  Vanessa
*  MARS 2006
**********************************************************

* Ouvertures des fichiers
EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"

OPEN "","ACCORD" TO F.ACCORD ELSE PRINT "OUVERTURE ACCORD" ;* en lecture
OPEN "","AGGIRAIDE" TO F.AGGIRAIDE ELSE PRINT "OUVERTURE AGGIRAIDE" ;* en lecture
OPEN "","ASSOCIATION" TO F.ASSOCIATION ELSE PRINT "OUVERTURE ASSOCIATION" ;* en lecture
OPEN "","BESOINSAIDE" TO F.BESOINSAIDE ELSE PRINT "OUVERTURE BESOINSAIDE" ;* en lecture
OPEN "","CIVILAIDANT" TO F.CIVILAIDANT ELSE PRINT "OUVERTURE CIVILAIDANT" ;* en lecture
OPEN "","CIVILAIDE" TO F.CIVILAIDE ELSE PRINT "OUVERTURE CIVILAIDE" ;* en lecture
OPEN "","COMPTEUR" TO F.COMPTEUR ELSE PRINT "OUVERTURE COMPTEUR" ;* en lecture
OPEN "","DEMANDACC" TO F.DEMANDACC ELSE PRINT "OUVERTURE DEMANDACC" ;* en lecture
OPEN "","ENVIRONAIDE" TO F.ENVIRONAIDE ELSE PRINT "OUVERTURE ENVIRONAIDE" ;* en lecture
OPEN "","FEDEASSOC" TO F.FEDEASSOC ELSE PRINT "OUVERTURE FEDEASSOC" ;* en lecture
OPEN "","FUSION" TO F.FUSION ELSE PRINT "OUVERTURE FUSION" ;* en lecture criture
OPEN "","ORGPRISECHARGE" TO F.ORGPRISECHARGE ELSE PRINT "OUVERTURE ORGPRISECHARGE" ;* en lecture
OPEN "","RESPONSABLE" TO F.RESPONSABLE ELSE PRINT "OUVERTURE RESPONSABLE" ;* en lecture
OPEN "","SECTEUR" TO F.SECTEUR ELSE PRINT "OUVERTURE SECTEUR" ;* en lecture
OPEN "","TABLES" TO F.TABLES ELSE PRINT "OUVERTURE TABLES" ;* en lecture
OPEN "","TEMPO" TO F.TEMPO ELSE PRINT "OUVERTURE TEMPO" ;* en lecture
OPEN "","TPSDETAILSINTERV" TO F.TPSDETAILSINTERV ELSE PRINT "OUVERTURE TPSDETAILSINTERV" ;* en lecture
OPEN "","TPSOBS" TO F.TPSOBS ELSE PRINT "OUVERTURE TPSOBS" ;* en lecture 
* Modif Guillaume DA10120 02/06/2010
OPEN "","RESSOURCESAIDE" TO F.RESSOURCESAIDE ELSE PRINT "OUVERTURE RESSOURCESAIDE";* en lecture
OPEN "","SSIADSOINS" TO F.SSIADSOINS ELSE PRINT "OUVERTURE SSIADSOINS";* en lecture
OPEN "","TPSSEMAINETYPE" TO F.TPSSEMAINETYPE ELSE PRINT "OUVERTURE TPSSEMAINETYPE";* en lecture
* Anthony 15/06/12
OPEN "","INTERVENANTEXT" TO F.INTERVENANTEXT ELSE PRINT "OUVERTURE INTERVENANTEXT";* en lecture
* Grgory - 02/07/12
OPEN "","ELTSFACTAIDE" TO F.ELTSFACTAIDE ELSE PRINT "OUVERTURE ELTSFACTAIDE";* en lecture
OPEN "","ABSENCESAIDE" TO F.ABSENCESAIDE ELSE PRINT "OUVERTURE ABSENCESAIDE" ;*en lecture
*********************************************************
* initialisation des variables

W_Tab=""
W_TabAssoc=""
W_ListeJour=""
W_ListeHreDeb=""
W_ListeHreFin=""
W_ListeFreq=""
W_ListeDateDeb=""
W_ListeDateFin=""
W_ListeCodeAidantRempl=""
W_ListeNomAidantRempl=""
W_ListePrenomAidantRempl=""
W_ListeTache=""
W_Besoin=""
W_ReqAcc=""
W_ReqFede=""
W_ReqSemType=""

W_CodeAidantRempl=""
W_NomAidantRempl=""
W_PrenomAidantRempl=""
W_NomPrenomAidantRempl=""

ENR_CIVILAIDANTREMPL=""
ENR_SECTEURAIDANT=""
ENR_AIDETECHNIQUE=""
READ ENR_AIDETECHNIQUE FROM F.TABLES, "AIDETECHNIQUE" ELSE ENR_AIDETECHNIQUE=""
*********************************************************
*  Rcupration des arguments

PROCREAD ARGUMENTS ELSE STOP
W_Aidant=FIELD(ARGUMENTS," ",2)
W_Aide=FIELD(ARGUMENTS," ",3)
W_DateDeb=FIELD(ARGUMENTS," ",4)
W_DateFin=FIELD(ARGUMENTS," ",5)
W_CleFichier=FIELD(ARGUMENTS," ",6)
W_Assoc=FIELD(ARGUMENTS," ",7)
*********************************************************
*  PROGRAMME PRINCIPAL

	W_CodeIntervExt = ""
	W_NomIntervExt = ""
	W_TelIntervExt = ""
	W_MailIntervExt = ""
	W_ObsIntervExt = ""
	W_TypeIntervExt = ""

	READ ENR_VOIE FROM F.TABLES,"NATUREVOIE" ELSE ENR_VOIE=""
	READ ENR_TITRE FROM F.TABLES,"TITRES" ELSE ENR_TITRE=""
	READ ENR_DEFTECH FROM F.TABLES,"DEFTECH" ELSE ENR_DEFTECH=""
	READ ENR_AUTRINTERVENANT FROM F.TABLES,"AUTRINTERVENANT" ELSE ENR_AUTRINTERVENANT=""
	
	W_Tab="AidantCode;AidantTitre;AidantNom;AidantPrenom;AidantAdresse1;AidantComplAdr;AidantCodPost;AidantCommune;AidantTel;"
	* Modif Greg - 28/11/11 - DA11128 - Ajout de nouveaux champs pour l'adresse du secteur de l'aidant
	W_Tab=W_Tab:'Adresse1Secteur;Adresse2Secteur;CodePostalSecteur;CommuneSecteur;Tel1Secteur;Tel2Secteur;'
	* Modif Greg - 28/11/11 - DA11128 - Ajout de la date de naissance de l'aid
	* Modif Greg - 02/07/12 - DA12067 - Ajout de la date de dcs de l'aid et du 2me numro de tel
	W_Tab=W_Tab:"AideCode;AideTitre;AideNom;AidePrenom;AideNomPatro;AideAdresse1;AideComplAdr;AideCodPost;AideCommune;AideTel;Tlphone2Aid;AideResponsable;"
	* Modif Greg - 28/11/11 - DA11128 - Ajout des donnes du secteur de l'aid
	W_Tab=W_Tab:"AideSecteur;Adresse1SecteurAide;Adresse2SecteurAide;CodePostalSecteurAide;CommuneSecteurAide;Tel1SecteurAide;Tel2SecteurAide;ObsSecteurAide;"
	
	W_Tab=W_Tab:"AideGroupeGIR;AideSsGroupeGIR;AideBesoins;AideModalitesIntervention;AideJrsFeriesTravaillees;AideDateNais;DateDecesAid;"
	* Modif Greg - 28/11/11 - DA11128 - Ajout de nouveaux champs pour la personne  prvenir en cas d'urgence.
	W_Tab=W_Tab:'AidePersPrevenirUrgence;AideReferentUrgence;AideTel1Urgence;AideTel2Urgence;AideEmailUrgence;AideObsUrgence;'
	* Modif Greg - 28/11/11 - DA11128 - Ajout d'un champ pour les aides techniques de l'aid
	* Anthony 14/06/12 Ajout situation familiale; personne au foyer et intervenant extrieur
	W_Tab=W_Tab:'AidesTechniques;SituationFamilialeAide;NomPersFoyer;PrenomPersFoyer;DateNaissPersFoyer;LienPersFoyer;RattachFoyerPersFoyer;CodeIntervExt;TypeIntervExt;NomIntervExt;TelIntervExt;MailIntervExt;ObsIntervExt;'
	* Modif Greg - 25/06/12 - Ajout des donnes de l'entourage
	W_Tab=W_Tab:'NomPrenomEntourage;EmailEntourage;TelEntourage;PortEntourage;NatureLienEntourage;LieuResidEntourage;'
	
	
* Guillaume 02/06/2010 - rajoute des champs de fusion
	* Modif Greg - 02/07/12 - Ajout du type d'organisme
	W_Tab=W_Tab:"AccordOrganisme;TypeOrgAccord;AccordDateDebut;AccordDateFin;AccordHresAllouees;AccordPartBenef;AccordNoDossier;AccordMotif;AideQuotFam;"
	W_Tab=W_Tab:"AssocSigle;AssocRaison;AssocAdresse1;AssocComplAdr;AssocCodPost;AssocCommune;AssocExtCedex;AssocTel;AssocFax;AssocEMail;AssocAgrement;AssocDateAgrement;"
	W_Tab=W_Tab:"PlanningJourInterv;PlanningHreDebInterv;PlanningHreFinInterv;PlanningFreqDetailInterv;DateDeb;DateFin;CodeAidantRemplace;NomAidantRemplace;PrenomAidantRemplace;NomPrenomAidantRemplace;"
	* modif vanessa 15/06/11 rajoute le champ PlanningTache
	W_Tab=W_Tab:"PlanningTache;PlanningObsOrdreMission;PlanningObservation;"
	* modif vanessa le 31/03/09, Guillaume 02/06/2010 - rajoute des champs de fusion
	W_Tab=W_Tab:"AideInfoPlanning;AideCle;AideNomPersonneUrgence;AideTelPersonneUrgence;AideObsPersonneUrgence;NomResponsable;TelResponsable;"
	
	* Modif Greg - 02/07/12 - Ajout des donnes de facturation de l'aid
	W_Tab=W_Tab:"DestinataireFacturation;1reLigneAdresseFacturation;ComplmentAdresseFacturation;CodePostalFacturation;VilleFacturation;CedexFacturation;"
	* Modif Greg - 02/07/12 - Ajout du NIR de l'aid
	W_Tab=W_Tab:"NumScuritSocialeAid;ClNumScuritSocialeAid;"
	* Modif Greg - 02/07/12 - Ajout des absences de l'aid
	W_Tab=W_Tab:"DateDbutAbsence;DateFinAbsence;MotiflibellAbsence;Hopital;Observation#"
	
* DONNEES AIDANT
	READ ENR_CIVILAIDANT FROM F.CIVILAIDANT,W_Aidant ELSE ENR_CIVILAIDANT=""
	READ ENR_SECTEURAIDANT FROM F.SECTEUR, ENR_CIVILAIDANT<31> ELSE ENR_SECTEURAIDANT=""
	
	j=1
	LOOP
	UNTIL ENR_CIVILAIDANT<1>=ENR_TITRE<2,j> OR ENR_TITRE<2,j>="" DO
		j=j+1
	REPEAT
	
	W_Fic=ENR_CIVILAIDANT
	W_Att=5
	GOSUB 10
	
	W_Tab=W_Tab:W_Aidant:";":ENR_TITRE<3,j>:";":ENR_CIVILAIDANT<2>:";":ENR_CIVILAIDANT<3>:";":W_Adresse:";":ENR_CIVILAIDANT<9>:";":ENR_CIVILAIDANT<10>:";":ENR_CIVILAIDANT<11>:";"
	IF ENR_CIVILAIDANT<44>="1" THEN
		W_Tab=W_Tab:";"
	END ELSE
		W_Tab=W_Tab:ENR_CIVILAIDANT<12>:";"
	END
	
	* Modif Greg - 28/11/11 - DA11128 - Ajout de l'adresse du secteur de l'aidant
	W_Adresse1Secteur=TRIM(ENR_SECTEURAIDANT<5>:' ':ENR_SECTEURAIDANT<6>:' ':ENR_SECTEURAIDANT<7>:' ':ENR_SECTEURAIDANT<8>)
	W_Tab=W_Tab:W_Adresse1Secteur:';':ENR_SECTEURAIDANT<9>:';':ENR_SECTEURAIDANT<10>:';':ENR_SECTEURAIDANT<11>:';':ENR_SECTEURAIDANT<14>:';':ENR_SECTEURAIDANT<16>:';'
	
* DONNEES AIDE
	READ ENR_CIVILAIDE FROM F.CIVILAIDE,W_Aide ELSE ENR_CIVILAIDE=""
	READ ENR_RESPONSABLE FROM F.RESPONSABLE,ENR_CIVILAIDE<39> ELSE ENR_RESPONSABLE=""
	READ ENR_SECTEUR FROM F.SECTEUR,ENR_CIVILAIDE<40>[1,3] ELSE ENR_SECTEUR=""
	READ ENR_AGGIRAIDE FROM F.AGGIRAIDE,W_Aide ELSE ENR_AGGIRAIDE=""
	READ ENR_BESOINSAIDE FROM F.BESOINSAIDE,W_Aide ELSE ENR_BESOINSAIDE=""
	READ ENR_ENVIRONAIDE FROM F.ENVIRONAIDE,W_Aide ELSE ENR_ENVIRONAIDE=""
	
	j=1
	LOOP
	UNTIL ENR_CIVILAIDE<1>=ENR_TITRE<2,j> OR ENR_TITRE<2,j>="" DO
		j=j+1
	REPEAT
	
	W_Fic=ENR_CIVILAIDE
	W_Att=5
	GOSUB 10
	
	W_Tab=W_Tab:W_Aide:";":ENR_TITRE<3,j>:";":ENR_CIVILAIDE<2>:";":ENR_CIVILAIDE<3>:";":ENR_CIVILAIDE<4>:";":W_Adresse:";":ENR_CIVILAIDE<9>:";":ENR_CIVILAIDE<10>:";":ENR_CIVILAIDE<11>:";"
	* Modif Greg - 02/07/12 - Ajout 2me num tel
	IF ENR_CIVILAIDE<46>="1" THEN
		W_Tab=W_Tab:";;"
	END ELSE
		W_Tab=W_Tab:ENR_CIVILAIDE<14>:";":ENR_CIVILAIDE<16>:";"
	END
	
	W_Tab=W_Tab:ENR_RESPONSABLE<1>:";"

	* Modif Greg - 02/07/12 - Ajout des donnes du secteur de l'aid
	W_Adresse1SecteurAide=TRIM(ENR_SECTEUR<5>:' ':ENR_SECTEUR<6>:' ':ENR_SECTEUR<7>:' ':ENR_SECTEUR<8>)
	W_Tab=W_Tab:ENR_SECTEUR<1>:';':W_Adresse1SecteurAide:';':ENR_SECTEUR<9>:';':ENR_SECTEUR<10>:';':ENR_SECTEUR<11>:';':ENR_SECTEUR<14>:';':ENR_SECTEUR<16>:';':ENR_SECTEUR<15>:';'
	* Fin modif Greg - 02/07/12
	
	
	W_Tab=W_Tab:ENR_AGGIRAIDE<19>:";":ENR_AGGIRAIDE<20>:";"
	
	* MODIF VANESSA 15/06/11
    READ ENR_TPSOBS FROM F.TPSOBS,W_Aidant:W_Aide ELSE ENR_TPSOBS=""
	IF ENR_TPSOBS<3> # "" THEN
		W_Besoin=ENR_TPSOBS<3>
	END ELSE
		* semaine type
		GOSUB 60
		IF W_Besoin="" THEN
			W_Count=DCOUNT(ENR_BESOINSAIDE<2>,CHAR(253))
			FOR i=1 TO W_Count
				IF ENR_BESOINSAIDE<2,i> # "" AND ENR_BESOINSAIDE<2,i> # "0" THEN
					W_Besoin=W_Besoin:ENR_DEFTECH<3,i>:"|"
				END
			NEXT i
			IF W_Besoin<>"" THEN W_Besoin=W_Besoin[1,LEN(W_Besoin)-1]
		END
	END
	* Modif Greg - 28/11/11 - DA11128 - Ajout de la date de naissance
	* Modif Greg - 02/07/12 - DA12067 - Ajout de la date de dcs
	W_Tab=W_Tab:W_Besoin:";":ENR_BESOINSAIDE<5>:";":ENR_BESOINSAIDE<7>:";":OCONV(ENR_CIVILAIDE<20>,"D4/"):";":OCONV(ENR_CIVILAIDE<48>,"D4/"):";"
	
* Modif Greg - 28/11/11 - DA11128 - AJout des donnes concernant la personne  prvenir en cas d'urgence
	IF ENR_ENVIRONAIDE<9><>"" THEN
		W_Referent="Non"
		IF ENR_ENVIRONAIDE<24>="1" THEN W_Referent="Oui"
	END ELSE
		W_Referent=""
	END
	W_Tab=W_Tab:ENR_ENVIRONAIDE<9>:';':W_Referent:';':ENR_ENVIRONAIDE<10>:';':ENR_ENVIRONAIDE<25>:';':ENR_ENVIRONAIDE<26>:';':ENR_ENVIRONAIDE<11>:';'

* Modif Greg - 28/11/11 - DA11128 - Ajout des aides techniques de l'aid
	W_AideTechnique=""
	FOR I = 1 TO DCOUNT(ENR_ENVIRONAIDE<19>,CHAR(253))
		FOR J = 1 TO DCOUNT(ENR_AIDETECHNIQUE<2>,CHAR(253))
			IF ENR_ENVIRONAIDE<19,I>=ENR_AIDETECHNIQUE<2,J> THEN
				IF W_AideTechnique<>"" THEN W_AideTechnique=W_AideTechnique:'|'
				W_AideTechnique=W_AideTechnique:ENR_AIDETECHNIQUE<3,J>
				EXIT
			END
		NEXT J
	NEXT I
	W_Tab=W_Tab:W_AideTechnique:';'

* Modif Anthony 14/06/12 Ajout situation familiale, personne au foyer, intervenant extrieur
	BEGIN CASE
		CASE ENR_CIVILAIDE<25> = "1"
            W_SituFamil="Mari(e)"
		CASE ENR_CIVILAIDE<25> = "2"
            W_SituFamil="Clibataire"
		CASE ENR_CIVILAIDE<25> = "3"
            W_SituFamil="Veuf(ve)"
		CASE ENR_CIVILAIDE<25> = "4"
            W_SituFamil="Divorc(e)" 
		CASE ENR_CIVILAIDE<25> = "5"
            W_SituFamil="Vie maritale"
		CASE ENR_CIVILAIDE<25> = "6"
            W_SituFamil="Spar(e)"
		CASE ENR_CIVILAIDE<25> = "7"
            W_SituFamil="PACS"
	END CASE 
	W_Tab=W_Tab:W_SituFamil:';'
	
	W_NomPersFoyer=""
	W_PrePersFoyer=""
	W_DatNaisPersFoyer=""
	W_LienPersFoyer=""
	W_RattachPersFoyer=""	
	
	FOR I = 1 TO DCOUNT(ENR_CIVILAIDE<34>,CHAR(253))
		W_NomPersFoyer = W_NomPersFoyer:ENR_CIVILAIDE<34,I>:'|'
		W_PrePersFoyer = W_PrePersFoyer:ENR_CIVILAIDE<35,I>:'|'
		W_DatNaisPersFoyer = W_DatNaisPersFoyer:OCONV(ENR_CIVILAIDE<36,I>,"D4/"):'|'
		BEGIN CASE
			CASE ENR_CIVILAIDE<37,I> = "1"
				W_LienPersFoyer=W_LienPersFoyer:"Enfant":'|'
			CASE ENR_CIVILAIDE<37,I> = "2"
				W_LienPersFoyer=W_LienPersFoyer:"Petit-enfant":'|'
			CASE ENR_CIVILAIDE<37,I> = "3"
				W_LienPersFoyer=W_LienPersFoyer:"Parent":'|'
			CASE ENR_CIVILAIDE<37,I> = "4"
				W_LienPersFoyer=W_LienPersFoyer:"Grand-parent" :'|'
			CASE ENR_CIVILAIDE<37,I> = "5"
				W_LienPersFoyer=W_LienPersFoyer:"Frre ou soeur":'|'
			CASE ENR_CIVILAIDE<37,I> = "6"
				W_LienPersFoyer=W_LienPersFoyer:"Autre":'|'
		END CASE 
		IF ENR_CIVILAIDE<38,I>[1,1]="O" THEN
			W_RattachPersFoyer = W_RattachPersFoyer:"Oui":'|'
		END ELSE 
			W_RattachPersFoyer = W_RattachPersFoyer:"Non":'|'
		END
	NEXT I
	
	IF DCOUNT(ENR_CIVILAIDE<34>,CHAR(253)) > 0 THEN
		W_NomPersFoyer=W_NomPersFoyer[1,LEN(W_NomPersFoyer)-1]
		W_PrePersFoyer=W_PrePersFoyer[1,LEN(W_PrePersFoyer)-1]
		W_DatNaisPersFoyer=W_DatNaisPersFoyer[1,LEN(W_DatNaisPersFoyer)-1]
		W_LienPersFoyer=W_LienPersFoyer[1,LEN(W_LienPersFoyer)-1]
		W_RattachPersFoyer=W_RattachPersFoyer[1,LEN(W_RattachPersFoyer)-1]
		
		W_Tab=W_Tab:W_NomPersFoyer:';':W_PrePersFoyer:';':W_DatNaisPersFoyer:';':W_LienPersFoyer:';':W_RattachPersFoyer:';'
	END ELSE 
		W_Tab=W_Tab:';;;;;'
	END
	
	W_CodeIntervExt=""
	W_NomIntervExt=""
	W_TelIntervExt=""
	W_MailIntervExt=""
	W_ObsIntervExt=""
	W_TypeIntervExt=""
	
	W_CountIntervExt15=DCOUNT(ENR_ENVIRONAIDE<15>,CHAR(253))
	W_CountIntervExt16=DCOUNT(ENR_ENVIRONAIDE<16>,CHAR(253))
	IF W_CountIntervExt15 > W_CountIntervExt16 THEN
		W_CountIntervExt=W_CountIntervExt15
	END ELSE
		W_CountIntervExt=W_CountIntervExt16
	END
	FOR I = 1 TO W_CountIntervExt
		IF ENR_ENVIRONAIDE<16,I> # "" THEN
			READ ENR_INTERVENANTEXT FROM F.INTERVENANTEXT,ENR_ENVIRONAIDE<16,I> THEN
				W_CodeIntervExt = W_CodeIntervExt:ENR_ENVIRONAIDE<16,I>:'|'
				W_NomIntervExt = W_NomIntervExt:ENR_INTERVENANTEXT<2>:" ":ENR_INTERVENANTEXT<3>:'|'
				W_TelIntervExt = W_TelIntervExt:ENR_INTERVENANTEXT<13>:'|'
				W_MailIntervExt = W_MailIntervExt:ENR_INTERVENANTEXT<27>:'|'
				W_ObsIntervExt = W_ObsIntervExt:ENR_INTERVENANTEXT<23>:'|'
				FOR J=1 TO DCOUNT(ENR_AUTRINTERVENANT<2>,CHAR(253))
					IF ENR_AUTRINTERVENANT<2,J>=ENR_INTERVENANTEXT<1> THEN
						W_TypeIntervExt = W_TypeIntervExt:ENR_AUTRINTERVENANT<3,J>:'|'
					END
				NEXT J
			END
		END ELSE
			W_CodeIntervExt = W_CodeIntervExt:ENR_ENVIRONAIDE<16,I>:'|'
			W_NomIntervExt = W_NomIntervExt:ENR_ENVIRONAIDE<17,I>:'|'
			W_TelIntervExt = W_TelIntervExt:ENR_ENVIRONAIDE<18,I>:'|'
			W_MailIntervExt = W_MailIntervExt:ENR_ENVIRONAIDE<22,I>:'|'
			W_ObsIntervExt = W_ObsIntervExt:ENR_ENVIRONAIDE<21,I>:'|'
			FOR J=1 TO DCOUNT(ENR_AUTRINTERVENANT<2>,CHAR(253))
				IF ENR_AUTRINTERVENANT<2,J>=ENR_ENVIRONAIDE<15,I> THEN
					W_TypeIntervExt = W_TypeIntervExt:ENR_AUTRINTERVENANT<3,J>:'|'
				END
			NEXT J		
		END
	NEXT I
	
	IF W_CountIntervExt > 0 THEN
		W_CodeIntervExt=W_CodeIntervExt[1,LEN(W_CodeIntervExt)-1]
		W_TypeIntervExt=W_TypeIntervExt[1,LEN(W_TypeIntervExt)-1]
		W_NomIntervExt=W_NomIntervExt[1,LEN(W_NomIntervExt)-1]
		W_TelIntervExt=W_TelIntervExt[1,LEN(W_TelIntervExt)-1]
		W_MailIntervExt=W_MailIntervExt[1,LEN(W_MailIntervExt)-1]
		W_ObsIntervExt=W_ObsIntervExt[1,LEN(W_ObsIntervExt)-1]
		
		W_Tab=W_Tab:W_CodeIntervExt:";":W_TypeIntervExt:";":W_NomIntervExt:';':W_TelIntervExt:';':W_MailIntervExt:";":W_ObsIntervExt:";"
	END ELSE 
		W_Tab=W_Tab:';;;;;;'
	END
*Fin modif Antho
	
	* Modif Greg - 25/06/12 - Ajout des donnes de l'entourage
	IF ENR_ENVIRONAIDE<5><>"" THEN
		W_NomPrenomEntourage=""
		W_EmailEntourage=""
		W_TelEntourage=""
		W_PortEntourage=""
		W_NatureLienEntourage=""
		W_LieuResidEntourage=""
		FOR IEntour=1 TO DCOUNT(ENR_ENVIRONAIDE<5>,CHAR(253))	
			W_LienEntourage=""
			BEGIN CASE
				CASE ENR_ENVIRONAIDE<20,IEntour> = "1"
					W_LienEntourage="Enfant"
				CASE ENR_ENVIRONAIDE<20,IEntour> = "2"
					W_LienEntourage="Petit-enfant"
				CASE ENR_ENVIRONAIDE<20,IEntour> = "3"
					W_LienEntourage="Parent"
				CASE ENR_ENVIRONAIDE<20,IEntour> = "4"
					W_LienEntourage="Grand-parent"
				CASE ENR_ENVIRONAIDE<20,IEntour> = "5"
					W_LienEntourage="Frre ou soeur"
				CASE ENR_ENVIRONAIDE<20,IEntour> = "6"
					W_LienEntourage="Voisin"
				CASE ENR_ENVIRONAIDE<20,IEntour> = "7"
					W_LienEntourage="Ami"
				CASE ENR_ENVIRONAIDE<20,IEntour> = "8"
					W_LienEntourage="Tuteur/curateur"
				CASE ENR_ENVIRONAIDE<20,IEntour> = "9"
					W_LienEntourage="Autre"
			END CASE 		
		
			W_NomPrenomEntourage=W_NomPrenomEntourage:ENR_ENVIRONAIDE<5,IEntour>
			W_EmailEntourage=W_EmailEntourage:ENR_ENVIRONAIDE<23,IEntour>
			W_TelEntourage=W_TelEntourage:ENR_ENVIRONAIDE<8,IEntour>
			W_PortEntourage=W_PortEntourage:ENR_ENVIRONAIDE<6,IEntour>
			W_NatureLienEntourage=W_NatureLienEntourage:W_LienEntourage
			W_LieuResidEntourage=W_LieuResidEntourage:ENR_ENVIRONAIDE<7,IEntour>
			
			IF IEntour<DCOUNT(ENR_ENVIRONAIDE<5>,CHAR(253)) THEN
				W_NomPrenomEntourage=W_NomPrenomEntourage:'|'
				W_EmailEntourage=W_EmailEntourage:'|'
				W_TelEntourage=W_TelEntourage:'|'
				W_PortEntourage=W_PortEntourage:'|'
				W_NatureLienEntourage=W_NatureLienEntourage:'|'
				W_LieuResidEntourage=W_LieuResidEntourage:'|'
			END
		NEXT IEntour
		
		W_Tab=W_Tab:W_NomPrenomEntourage:';':W_EmailEntourage:';':W_TelEntourage:';':W_PortEntourage:';':W_NatureLienEntourage:';':W_LieuResidEntourage:';'
	END ELSE
		W_Tab=W_Tab:';;;;;;'
	END
	
	* Fin modif Greg - 25/06/12
	
	
* ACCORD
	GOSUB 20
	W_HreAllouee=TRIM(W_HreAllouee "R26(#10)")
	W_PartBenef=TRIM(W_PartBenef "R26(#10)")
	* Modif Greg - 02/07/12 - Ajout du type d'organisme
	IF ENR_ORGPRISECHARGE<18> = "P" THEN
		W_TypeOrg = "Principal"
	END ELSE
		W_TypeOrg = "Complmentaire"
	END	
	W_Tab=W_Tab:ENR_ORGPRISECHARGE<1>:";":W_TypeOrg:";":OCONV(W_DebAcc,"D4/"):";":OCONV(W_FinAcc,"D4/"):";":W_HreAllouee:";":W_PartBenef:";"
	
	* Modif Guillaume DA10120 02/06/2010
	W_AideQuotFam = ""
    READ ENR_RESSOURCESAIDE FROM F.RESSOURCESAIDE, W_Aide THEN
        W_AideQuotFam = ENR_RESSOURCESAIDE<6> / 100
    END
    W_Tab=W_Tab:W_AccordNoDossier:";":W_AccordMotif:";":W_AideQuotFam:";"
	
* ENTITE JURIDIQUE
	
	READ ENR_COMPTEUR FROM F.COMPTEUR,"999" ELSE ENR_COMPTEUR=""
	IF ENR_COMPTEUR<17>="" THEN
		READ ENR_ASSOCIATION FROM F.ASSOCIATION,W_Assoc ELSE ENR_ASSOCIATION=""
		W_TabAssoc=ENR_ASSOCIATION
	END ELSE
		GOSUB 30
		W_TabAssoc=ENR_FEDEASSOC
	END
	
	W_Fic=W_TabAssoc
	W_Att=3
	GOSUB 10
	W_Tab=W_Tab:W_TabAssoc<1>:";":W_TabAssoc<2>:";":W_Adresse:";":W_TabAssoc<7>:";":W_TabAssoc<8>:";":W_TabAssoc<9>:";"
	W_Tab=W_Tab:W_TabAssoc<11>:";":W_TabAssoc<12>:";":W_TabAssoc<13>:";"
	IF ENR_COMPTEUR<17>="" THEN
		W_Tab=W_Tab:W_TabAssoc<35>:";":W_TabAssoc<23>:";":OCONV(W_TabAssoc<24>,"D4/"):";"
	END ELSE
		W_Tab=W_Tab:W_TabAssoc<14>:";":W_TabAssoc<16>:";":OCONV(W_TabAssoc<17>,"D4/"):";"
	END
	
* DETAIL INTERVENTION
	READ ENR_TEMPO FROM F.TEMPO,W_CleFichier ELSE ENR_TEMPO=""
	W_Count=DCOUNT(ENR_TEMPO,CHAR(254))

	FOR i = 1 TO W_Count
      		READ ENR_TPSDETAILSINTERV FROM F.TPSDETAILSINTERV,ENR_TEMPO<i> ELSE ENR_TPSDETAILSINTERV=""
		W_Jour=ENR_TEMPO<i>[22,1]
		GOSUB 40
		
		W_HreDeb = INT(ENR_TEMPO<i>[25,2] / 100 * 60)
		W_HreDeb = ENR_TEMPO<i>[23,2]:" h ":W_HreDeb "R%2"
		W_HreFin = INT(ENR_TPSDETAILSINTERV<2>[3,2] / 100 * 60)
		W_HreFin = ENR_TPSDETAILSINTERV<2>[1,2]:" h ":W_HreFin "R%2"
		
		W_PlgDateDeb=OCONV(ENR_TEMPO<i>[11,5], "D4/")
		W_PlgDateFin=OCONV(ENR_TPSDETAILSINTERV<1>, "D4/")
		
		IF ENR_TPSDETAILSINTERV<6>#"" THEN
			READ ENR_CIVILAIDANTREMPL FROM F.CIVILAIDANT, ENR_TPSDETAILSINTERV<6>[1,5] THEN
				W_CodeAidantRempl=ENR_TPSDETAILSINTERV<6>[1,5]
				W_NomAidantRempl=ENR_CIVILAIDANTREMPL<2>
				W_PrenomAidantRempl=ENR_CIVILAIDANTREMPL<3>
				W_NomPrenomAidantRempl=ENR_CIVILAIDANTREMPL<2>:" ":ENR_CIVILAIDANTREMPL<3>
			END ELSE
				W_CodeAidantRempl=""
				W_NomAidantRempl=""
				W_PrenomAidantRempl=""
				W_NomPrenomAidantRempl=""
			END
		END ELSE
			W_CodeAidantRempl=""
			W_NomAidantRempl=""
			W_PrenomAidantRempl=""
			W_NomPrenomAidantRempl=""
		END
		
		W_Frequence=ENR_TPSDETAILSINTERV<3>
		GOSUB 50
		
		* modif vanessa 15/06/11 - rajoute tache de l'intervention
		W_TacheInterv=""
		W_CountMV = DCOUNT(ENR_TPSDETAILSINTERV,CHAR(253))
		FOR j=1 TO W_CountMV
			IF LEN(ENR_TPSDETAILSINTERV<7,j>)=6 THEN
				READ ENR_SSIADSOINS FROM F.SSIADSOINS,ENR_TPSDETAILSINTERV<7,j> ELSE ENR_SSIADSOINS=""
				W_TacheInterv=W_TacheInterv:ENR_SSIADSOINS<1>:"*"
			END ELSE
				FOR iTable = 1 TO DCOUNT(ENR_DEFTECH<2>,CHAR(253))
					IF ENR_DEFTECH<2,iTable> = ENR_TPSDETAILSINTERV<7,j> THEN
						W_TacheInterv=W_TacheInterv:ENR_DEFTECH<3,iTable>:"*"
					END
				NEXT iTable
			END
			
		NEXT j
		
		W_ListeJour=W_ListeJour:W_Jour:CHAR(13):CHAR(10)
		W_ListeHreDeb=W_ListeHreDeb:W_HreDeb:CHAR(13):CHAR(10)
		W_ListeHreFin=W_ListeHreFin:W_HreFin:CHAR(13):CHAR(10)
		W_ListeFreq=W_ListeFreq:W_Frequence:CHAR(13):CHAR(10)
		W_ListeDateDeb=W_ListeDateDeb:W_PlgDateDeb:CHAR(13):CHAR(10)
		W_ListeDateFin=W_ListeDateFin:W_PlgDateFin:CHAR(13):CHAR(10)
		W_ListeCodeAidantRempl=W_ListeCodeAidantRempl:W_CodeAidantRempl:CHAR(13):CHAR(10)
		W_ListeNomAidantRempl=W_ListeNomAidantRempl:W_NomAidantRempl:CHAR(13):CHAR(10)
		W_ListePrenomAidantRempl=W_ListePrenomAidantRempl:W_PrenomAidantRempl:CHAR(13):CHAR(10)
		W_ListeNomPrenomAidantRempl=W_ListeNomPrenomAidantRempl:W_NomPrenomAidantRempl:CHAR(13):CHAR(10)
		W_ListeTache=W_ListeTache:W_TacheInterv:CHAR(13):CHAR(10)

	NEXT i
	
	W_Tab=W_Tab:W_ListeJour:";":W_ListeHreDeb:";":W_ListeHreFin:";":W_ListeFreq:";":W_ListeDateDeb:";":W_ListeDateFin:";":W_ListeCodeAidantRempl:";":W_ListeNomAidantRempl:";":W_ListePrenomAidantRempl:";":W_ListeNomPrenomAidantRempl:";":W_ListeTache:";"
	
* OBSERVATIONS
	W_Tab=W_Tab:ENR_TPSOBS<1>:";":ENR_TPSOBS<2>:";"
	
	* modif vanessa le 31/03/09 - rajoute des champs de fusion
* OBSERVATIONS AIDE
	W_Tab=W_Tab:ENR_BESOINSAIDE<17>:";"
	IF ENR_BESOINSAIDE<22>="O" THEN
		W_Cle="CLES"
	END ELSE
		W_Cle=""
	END
	W_Tab=W_Tab:W_Cle:";"
	
* REFERENT EN CAS DE BESOIN
	W_Tab=W_Tab:ENR_ENVIRONAIDE<9>:";":ENR_ENVIRONAIDE<10>:";":ENR_ENVIRONAIDE<11>:";"
	
* RESPONSABLE
	W_Tab=W_Tab:ENR_RESPONSABLE<1>:";":ENR_RESPONSABLE<11>:";"
	*** fin modif

	* Modif Greg - 02/07/12 - Ajout des donnes de facturation de l'aid
	READ ENR_ELTSFACTAIDE FROM F.ELTSFACTAIDE, W_Aide ELSE ENR_ELTSFACTAIDE=""
	IF ENR_ELTSFACTAIDE<8>#"" THEN
		W_AdresseFacturation=""
		W_AdresseFacturation=ENR_ELTSFACTAIDE<3> :" ": ENR_ELTSFACTAIDE<4> :" ": ENR_ELTSFACTAIDE<5> :" ": ENR_ELTSFACTAIDE<6>
		W_Tab=W_Tab:ENR_ELTSFACTAIDE<2>:";":W_AdresseFacturation:";":ENR_ELTSFACTAIDE<7>:";":ENR_ELTSFACTAIDE<8>:";":ENR_ELTSFACTAIDE<9>:";":ENR_ELTSFACTAIDE<11>:";"
	END ELSE
		W_DestinatFact=""
		W_DestinatFact=ENR_CIVILAIDE<1> :" ": ENR_CIVILAIDE<2> :" ": ENR_CIVILAIDE<3>
		
		W_Adresse=""
		W_Adresse=ENR_CIVILAIDE<5> :" ": ENR_CIVILAIDE<6> :" ": ENR_CIVILAIDE<7> :" ": ENR_CIVILAIDE<8>		
		W_Tab=W_Tab:W_DestinatFact:";":W_Adresse:";":ENR_CIVILAIDE<9> :";":ENR_CIVILAIDE<10> :";":ENR_CIVILAIDE<11>:";":ENR_CIVILAIDE<13>:";"
	END	

	* Modif Greg - 02/07/12 - Ajout du NIR de l'aid
	W_Tab=W_Tab:ENR_CIVILAIDE<18>:";":ENR_CIVILAIDE<19>:";"
	
	* Modif Greg - 02/07/12 - Ajout des absences de l'aid
	READ ENR_ABSENCESAIDE FROM F.ABSENCESAIDE, W_Aide ELSE ENR_ABSENCESAIDE=""
	IF ENR_ABSENCESAIDE<3,1> # "" THEN
		W_Tab=W_Tab:OCONV(ENR_ABSENCESAIDE<1,1>,"D4/"):";":OCONV(ENR_ABSENCESAIDE<2,1>,"D4/"):";":ENR_ABSENCESAIDE<3,1>:";"
	END ELSE
		IF ENR_ABSENCESAIDE<4,1> # "" THEN
			READ ENR_MOTIFSORTIE FROM F.TABLES,"MOTIFSORTIE" ELSE ENR_MOTIFSORTIE=""
			j=1
			LOOP
			UNTIL ENR_MOTIFSORTIE<2,j>=ENR_ABSENCESAIDE<4,1> OR ENR_MOTIFSORTIE<2,j>="" DO
				j=j+1
			REPEAT
			IF ENR_MOTIFSORTIE<2,j> # "" THEN
				W_Tab=W_Tab:OCONV(ENR_ABSENCESAIDE<1,1>,"D4/"):";":OCONV(ENR_ABSENCESAIDE<2,1>,"D4/"):";":ENR_MOTIFSORTIE<3,j>:";"
			END ELSE
				W_Tab=W_Tab:";;;"
			END
		END ELSE
			W_Tab=W_Tab:";;;"
		END
	END
	
	IF ENR_ABSENCESAIDE<5,1> <> "" THEN
		READ ENR_INTERVENANTEXT FROM F.INTERVENANTEXT, ENR_ABSENCESAIDE<5,1>THEN
			W_Tab=W_Tab:TRIM(TRIM(ENR_INTERVENANTEXT<2>):" ":ENR_INTERVENANTEXT<3>):";"
		END ELSE
			W_Tab=W_Tab:";"
		END
	END ELSE
		W_Tab=W_Tab:";"
	END
	W_Tab=W_Tab:ENR_ABSENCESAIDE<7,1>:"#"	
	
	WRITE W_Tab ON F.FUSION,W_CleFichier:".txt"
	DELETE F.TEMPO,W_CleFichier
	
STOP

********************************************************************************************************************
* mise en forme adresse
10

	W_Adresse=""
	IF W_Fic<W_Att> # "" THEN
		W_Adresse=W_Fic<W_Att>:" "
	END
	W_Att=W_Att+1
	IF W_Fic<W_Att> # "" THEN
		W_Adresse = W_Adresse:W_Fic<W_Att>:" "
	END
	W_Att=W_Att+1
	i=1
	LOOP
	UNTIL W_Fic<W_Att>=ENR_VOIE<2,i> OR ENR_VOIE<2,i>="" DO
		i=i+1
	REPEAT
	IF ENR_VOIE<2,i> # "" THEN
		W_Adresse = W_Adresse:ENR_VOIE<3,i>:" "
	END
	W_Att=W_Att+1
	IF W_Fic<W_Att> # "" THEN
		W_Adresse = W_Adresse:W_Fic<W_Att>:" "
	END
	
RETURN

********************************************************************************************************************
* REQUETE ACCORD
20

	W_DebAcc=""
	W_FinAcc=""
	W_HreAllouee=""
	W_PartBenef=""
	
   	W_End="FAUX"
	
	W_Temp='SSELECT ACCORD AVEC 18 = "" AND AVEC 0 = "':W_Aide:']" AND AVEC 5 <= "':W_DateFin:'"'
	W_Temp=W_Temp:' AND AVEC 6 >= "':W_DateDeb:'" AND AVEC TypeOrg = "P" PAR 8'
	
   	EXECUTE W_Temp
   	EXECUTE 'SAUVE-LISTE W_ReqAcc'
   	EXECUTE "LISTE W_ReqAcc" RETURNING MSGCODE
	
   	IF MSGCODE<1> # 209 THEN
	
      	SELECT F.ACCORD TO W_ReqAcc
   		LOOP
      		READNEXT W_Cle FROM W_ReqAcc ELSE W_End = "VRAI"
   		WHILE W_End = "FAUX" DO
		
      		READ ENR_ACCORD FROM F.ACCORD,W_Cle ELSE ENR_ACCORD=""
			READ ENR_ORGPRISECHARGE FROM F.ORGPRISECHARGE,ENR_ACCORD<1> ELSE ENR_ORGPRISECHARGE=""
			* Modif Guillaume DA10120 02/06/2010
			W_AccordNoDossier = ENR_ACCORD<2>
			W_AccordMotif = ""
            READ ENR_TABLESMotif FROM F.TABLES, "MOTIFACCORD" THEN 
                FOR iMotif = 1 TO DCOUNT(ENR_TABLESMotif<2>, CHAR(253))
                    IF ENR_TABLESMotif<2,iMotif> = ENR_ACCORD<3> THEN EXIT
                NEXT iMotif
                W_AccordMotif = ENR_TABLESMotif<3,iMotif>
            END
            * Fin modif Guillaume DA10120 02/06/2010
            
			W_DebAcc=ENR_ACCORD<5>
			W_FinAcc=ENR_ACCORD<6>
			W_HreAllouee=ENR_ACCORD<9>
			W_PartBenef=ENR_ACCORD<13,1>
			W_End="VRAI"
			
   		REPEAT
	END ELSE
	
      	READ ENR_DEMANDACC FROM F.DEMANDACC,W_Aide ELSE ENR_DEMANDACC=""
		W_Count=DCOUNT(ENR_DEMANDACC<1>,CHAR(253))
		FOR i = 1 TO W_Count
			READ ENR_ORGPRISECHARGE FROM F.ORGPRISECHARGE,ENR_DEMANDACC<1,i> ELSE ENR_ORGPRISECHARGE=""
			IF ENR_ORGPRISECHARGE<18>="P" THEN
				IF ENR_DEMANDACC<3,i> <= W_DateFin AND ENR_DEMANDACC<4,i> >= W_DateDeb THEN
					W_DebAcc=ENR_DEMANDACC<3,i>
					W_FinAcc=ENR_DEMANDACC<4,i>
					W_HreAllouee=ENR_DEMANDACC<5,i>
					W_PartBenef=ENR_DEMANDACC<6,i>
					EXIT 
				END
			END
		NEXT i
		
	END
	
RETURN

********************************************************************************************************************
* RECHERCHE FEDEASSOC
30

   	W_End="FAUX"
	
	W_Secteur=ENR_CIVILAIDE<40>[1,3]
	W_Temp='SSELECT FEDEASSOC AVEC 41 = "':W_Secteur:'"'
	
   	EXECUTE W_Temp
   	EXECUTE 'SAUVE-LISTE W_ReqFede'
   	EXECUTE "LISTE W_ReqFede" RETURNING MSGCODE
	
   	IF MSGCODE<1> # 209 THEN
      	SELECT F.FEDEASSOC TO W_ReqFede
   		LOOP
      		READNEXT W_Cle FROM W_ReqFede ELSE W_End = "VRAI"
   		WHILE W_End = "FAUX" DO
      		READ ENR_FEDEASSOC FROM F.FEDEASSOC,W_Cle ELSE ENR_FEDEASSOC=""
			W_End="VRAI"
			
   		REPEAT
	END
	
RETURN

********************************************************************************************************************
* RECHERCHE JOUR
40

	BEGIN CASE
		CASE W_Jour = "0"
            W_Jour="LUNDI"
		CASE W_Jour = "1"
            W_Jour="MARDI"
		CASE W_Jour = "2"
            W_Jour="MERCREDI"
		CASE W_Jour = "3"
            W_Jour="JEUDI" 
		CASE W_Jour = "4"
            W_Jour="VENDREDI"
		CASE W_Jour = "5"
            W_Jour="SAMEDI"
		CASE W_Jour = "6"
            W_Jour="DIMANCHE"
	END CASE 
	
RETURN

********************************************************************************************************************
* RECHERCHE FREQUENCE
50

	BEGIN CASE
		CASE W_Frequence = "1"
                  	W_Frequence="1/1"
		CASE W_Frequence = "2"
                  	W_Frequence="1/2"
		CASE W_Frequence = "3"
                  	W_Frequence="1/3"
		CASE W_Frequence = "4"
                  	W_Frequence="1/4" 
	END CASE 

RETURN

********************************************************************************************************************
* TACHES DANS LA SEMAINE TYPE
* RAJOUT VANESSA 15/06/11
60

   	W_Fini="FAUX"
	W_Temp='SSELECT TPSSEMAINETYPE AVEC @ID = "':W_Aide:']" AND AVEC DateDebSemType <= "':W_DateFin:'" AND AVEC DateFinSemType >= "':W_DateDeb:'" OR = ""'
	
   	EXECUTE W_Temp
   	EXECUTE 'SAUVE-LISTE W_ReqSemType'
   	EXECUTE "LISTE W_ReqSemType" RETURNING MSGCODE
	
   	IF MSGCODE<1> # 209 THEN
	
      	SELECT F.TPSSEMAINETYPE TO W_ReqSemType
   		LOOP
      		READNEXT W_CleSemType FROM W_ReqSemType ELSE W_Fini = "VRAI"
   		WHILE W_Fini = "FAUX" DO
		
      		READ ENR_TPSSEMAINETYPE FROM F.TPSSEMAINETYPE,W_CleSemType ELSE ENR_TPSSEMAINETYPE=""
			
			FOR iSemType=1 TO DCOUNT(ENR_TPSSEMAINETYPE<4>,CHAR(253))
				IF LEN(ENR_TPSSEMAINETYPE<4,iSemType>)=6 THEN
					READ ENR_SSIADSOINS FROM F.SSIADSOINS,ENR_TPSSEMAINETYPE<4,iSemType> ELSE ENR_SSIADSOINS=""
					W_Besoin=W_Besoin:ENR_SSIADSOINS<1>
				END ELSE
			        FOR iTable = 1 TO DCOUNT(ENR_DEFTECH<2>,CHAR(253))
			            IF ENR_DEFTECH<2,iTable> = ENR_TPSSEMAINETYPE<4,iSemType> THEN 
							W_Besoin=W_Besoin:ENR_DEFTECH<3,iTable>
						END
			        NEXT iTable				
				END
				
			NEXT iSemType
			
   		REPEAT
	END
	
RETURN