EXECUTE "SET-THOUS ."
EXECUTE "SET-DEC ,"
EXECUTE "DATE.FORMAT"
OPEN "", "CIVILAIDANT" TO F.CIVILAIDANT ELSE STOP
OPEN "", "CIVILAIDE" TO F.CIVILAIDE ELSE STOP
OPEN "", "HISTORCUMUL" TO F.HISTORCUMUL ELSE STOP
OPEN "", "TEMPO" TO F.TEMPO ELSE STOP


*********************************************
* PR ATTESTSAL - MICHAEL, le 27/11/02
*
* 	Dessin du fichier TEMPO en sortie :
*
* - 1 ligne par AIDANT
* - 1re MV = infos aidant en SV
* - Puis une MV par aide, infos aid en SV
*
* - Detail MV Aidant : 
* SV 1 : Code secteur (att. 31)
* SV 2 : Nom 
* SV 2 : prnom
* SV 3 : Adresse 1
* SV 4 : Cmplt adresse
* SV 5 : CP
* SV 6 : Ville
* SV 7 : Titre
* SV 8 : Total heures travaillees
* SV 9 : Total net imposable
* SV 10 : Total revenus activit
*
* - Detail MV employeur
* SV 1 : Nom
* SV 2 : prnom
* SV 3 : Adresse 1
* SV 4 : Cmplt adresse
* SV 5 : CP
* SV 6 : Ville
* SV 7 : heures travaillees
* SV 8 : net imposable


PROCREAD PARAMETRES ELSE STOP
W_TypeAct = FIELD(PARAMETRES, "|",2)
W_Annee = FIELD(PARAMETRES, "|", 3)
W_User = FIELD(PARAMETRES, "|", 4)
W_Tri = FIELD(PARAMETRES, "|", 5)
W_Asso = FIELD(PARAMETRES, "|",6)
W_BorneDeb = FIELD(PARAMETRES, "|",7)
W_BorneFin = FIELD(PARAMETRES, "|",8)

 
READ ENR_TEMPO FROM F.TEMPO,"ATTESTSAL":W_User ELSE
	ENR_TEMPO<1> = "Vide"
	WRITE  ENR_TEMPO ON F.TEMPO, "ATTESTSAL":W_User
	STOP
END

W_Str = 'SELECT HISTORCUMUL AVEC PeriodeHistCum = "':W_Annee:'" '
    
    IF W_TypeAct # "M" THEN
	W_Str = W_Str:'AND AVEC EmployeurHistCum = "':W_Asso:'" AND AVEC PrestManda = "P" '
    END ELSE
	W_Str = W_Str:'AND AVEC PrestManda = "M" '
    END

    IF W_Tri = "S" THEN
	IF ENR_TEMPO<1> # "" THEN
		W_COUNT = DCOUNT(ENR_TEMPO,CHAR(254))
		W_Str = W_Str:'AND AVEC CodeSecteurAidant = "':ENR_TEMPO<1>
		FOR i = 2 TO W_COUNT
			W_Str = W_Str:'" OR = "':ENR_TEMPO<i>
		NEXT i
		W_Str = W_Str:'" '
    	END ELSE
        	W_Str= W_Str:'PAR NomSecteurAidant '
      END
    END ELSE
    	IF W_Tri = "C" THEN
		IF ENR_TEMPO<1> # "" THEN
			W_COUNT = DCOUNT(ENR_TEMPO,CHAR(254))
			W_Str = W_Str:'AND AVEC NomCommuneAidant = "':ENR_TEMPO<1>
			FOR i = 2 TO W_COUNT
				W_Str = W_Str:'" OR = "':ENR_TEMPO<i>
			NEXT i
			W_Str = W_Str:'" '

		END ELSE
	            	W_Str = W_Str:'PAR NomCommuneAidant '
        	END
	END ELSE
		IF W_Tri = "I" THEN
			W_COUNT = DCOUNT(ENR_TEMPO,CHAR(254))
			W_Str = W_Str:'AND AVEC @ID = "':ENR_TEMPO<1>
			FOR i = 2 TO W_COUNT
				W_Str = W_Str:']" OR = "':ENR_TEMPO<i>
			NEXT i
			W_Str = W_Str:']" '
		END
	END
    END

	IF TRIM(W_BorneDeb:W_BorneFin) # "" THEN
		W_BorneFin = W_BorneFin:']'
		W_Str = W_Str:'AND AVEC NomAidant >= "':W_BorneDeb:'" AND AVEC NomAidant <= "':W_BorneFin:'" '
	END 

    IF W_Tri = "S" THEN
	W_Str = W_Str:' PAR NomSecteurAidant '
    END ELSE
	IF W_Tri = "C" THEN
		W_Str = W_Str:' PAR NomCommuneAidant '
	END
    END

    W_Str = W_Str:'PAR NomAidant PAR PrenomAidant PAR CodeAidant PAR NomAide PAR PrenomAide PAR EmployeurHistCum'

ENR_TEMPO = ""
W_ReqAttestSal = ""
EXECUTE W_Str
EXECUTE 'SAUVE-LISTE W_ReqAttestSal'
EXECUTE 'LISTE W_ReqAttestSal' RETURNING MSGCODE
IF MSGCODE<1> = 209 THEN
	ENR_TEMPO<1> = "Vide"
	WRITE ENR_TEMPO ON F.TEMPO, "ATTESTSAL":W_User
	STOP
END

SELECT F.HISTORCUMUL TO W_ReqAttestSal


W_Fin = "F"
W_Aidant = ""
W_IndLigne = 0
LOOP
    READNEXT W_Cle FROM W_ReqAttestSal ELSE W_Fin = "V"
WHILE W_Fin = "F"
    IF W_Cle[1,5] # W_Aidant THEN 
	W_Aidant = W_Cle[1,5]
	W_IndLigne = W_IndLigne + 1
	GOSUB 100
	W_IndAide = 1
	W_TamponAide = ""
    END
    READ ENR_HISTORCUMUL FROM F.HISTORCUMUL, W_Cle THEN
	IF W_Cle[10,5] # W_TamponAide THEN
		W_IndAide = W_IndAide + 1
		W_TamponAide = W_Cle[10,5]
		GOSUB 200
	END

	IF ENR_TEMPO<W_IndLigne,W_IndAide, 8> = "" THEN ENR_TEMPO<W_IndLigne,W_IndAide, 8> = 0
	IF ENR_TEMPO<W_IndLigne,W_IndAide, 7> = "" THEN ENR_TEMPO<W_IndLigne,W_IndAide, 7> = 0
	IF ENR_TEMPO<W_IndLigne,1,8> = "" THEN ENR_TEMPO<W_IndLigne,1,8> = 0
	IF ENR_TEMPO<W_IndLigne,1,9> = "" THEN ENR_TEMPO<W_IndLigne,1,9> = 0
	IF ENR_TEMPO<W_IndLigne,1,10> = "" THEN ENR_TEMPO<W_IndLigne,1,10> = 0

	ENR_TEMPO<W_IndLigne,W_IndAide, 7> = ENR_TEMPO<W_IndLigne,W_IndAide, 7> + ENR_HISTORCUMUL<2>
	ENR_TEMPO<W_IndLigne,W_IndAide, 8> = ENR_TEMPO<W_IndLigne,W_IndAide, 8> + ENR_HISTORCUMUL<6>
	ENR_TEMPO<W_IndLigne,1,8> = ENR_TEMPO<W_IndLigne,1,8> + ENR_HISTORCUMUL<2>
	ENR_TEMPO<W_IndLigne,1,9> = ENR_TEMPO<W_IndLigne,1,9> + ENR_HISTORCUMUL<6>
	ENR_TEMPO<W_IndLigne,1,10> = ENR_TEMPO<W_IndLigne,1,10> + (ENR_HISTORCUMUL<6>-ENR_HISTORCUMUL<20>)


    END
REPEAT

WRITE ENR_TEMPO ON F.TEMPO, "ATTESTSAL":W_User

EXECUTE 'EFFACER-LISTE W_ReqAttestSal'

STOP

100
***************************************************************
*    Traitement infos aidant
***************************************************************
READ ENR_CIVILAIDANT FROM F.CIVILAIDANT, W_Aidant THEN
	ENR_TEMPO<W_IndLigne,1,1> = ENR_CIVILAIDANT<31> 
	ENR_TEMPO<W_IndLigne,1,2> = ENR_CIVILAIDANT<2>
	ENR_TEMPO<W_IndLigne,1,3> = ENR_CIVILAIDANT<3>
	ENR_TEMPO<W_IndLigne,1,4> = TRIM(ENR_CIVILAIDANT<5>:" ":ENR_CIVILAIDANT<6>:" ":ENR_CIVILAIDANT<7>:" ":ENR_CIVILAIDANT<8>)
	ENR_TEMPO<W_IndLigne,1,5> = ENR_CIVILAIDANT<9>
	ENR_TEMPO<W_IndLigne,1,6> = TRIM(ENR_CIVILAIDANT<10>:" ": ENR_CIVILAIDANT<11>)
	ENR_TEMPO<W_IndLigne,1,7> = ENR_CIVILAIDANT<1>

END
RETURN
	
200
***************************************************************
*    Traitement infos aide
***************************************************************
READ ENR_CIVILAIDE FROM F.CIVILAIDE, W_TamponAide THEN
	ENR_TEMPO<W_IndLigne,W_IndAide,1> = ENR_CIVILAIDE<2> 
	ENR_TEMPO<W_IndLigne,W_IndAide,2> = ENR_CIVILAIDE<3>
	ENR_TEMPO<W_IndLigne,W_IndAide,4> = ENR_CIVILAIDE<9>
	ENR_TEMPO<W_IndLigne,W_IndAide,3> = TRIM(ENR_CIVILAIDE<5>:" ":ENR_CIVILAIDE<6>:" ":ENR_CIVILAIDE<7>:" ":ENR_CIVILAIDE<8>)
	ENR_TEMPO<W_IndLigne,W_IndAide,5> = ENR_CIVILAIDE<10>
	ENR_TEMPO<W_IndLigne,W_IndAide,6> = ENR_CIVILAIDE<11>
END
RETURN
