***************************************************
* Programme visant  gnrer un fichier contenant *
* les Anouveaux produits par le Menu INFOLOGIS   *
*                                                 *
* 06/01/03 -> Grgory                             *
*                                                 *
***************************************************
 * Ouverture des fichiers

EXECUTE "SET-THOUS ."
EXECUTE "DATE.FORMAT"
OPEN "","BROUILLARDDETAIL" TO F.BROUILLARDDETAIL ELSE PRINT "BROUILLARDDETAIL"
OPEN "","LIENCOMPTA" TO F.LIENCOMPTA ELSE PRINT "LIENCOMPTA"
OPEN "","PARAMENTITECOMPTA" TO F.PARAMENTITECOMPTA ELSE PRINT "PARAMENTITECOMPTA"

***************************************************
 * Dclaration des variables

W_Entite=""
W_DateEcriture=""
W_Montant=""
W_Cle=""
W_RESULTAT=""
W_FINI="FAUX"
W_Quantite=""
W_CodeAide=""
W_CodePiece=""
ENR_LIENCOMPTA=""
***************************************************
	
	EXECUTE 'SET-DEC .'
	
	PRINT "Entit juridique 3N":
	INPUT W_Entite
	EXECUTE 'SSELECT BROUILLARDDETAIL AVEC 0 = "':W_Entite:'99]"'

	EXECUTE 'SAUVE-LISTE W_RESULTAT'
	EXECUTE "LISTE W_RESULTAT" RETURNING MSGCODE
	IF MSGCODE<1>#209 THEN
		SELECT F.BROUILLARDDETAIL TO W_RESULTAT	
		GOSUB 100
		WRITE ENR_LIENCOMPTA ON F.LIENCOMPTA,"Anouveau":W_Entite:".txt"
	END ELSE
		ENR_LIENCOMPTA="RIEN"
		WRITE ENR_LIENCOMPTA ON F.LIENCOMPTA,"Anouveau":W_Entite:".txt"
	END

	EXECUTE 'SET-DEC ,'

STOP

***************************************************
* Traitement des A-nouveaux                       *
***************************************************
100

	I=0
	LOOP
		READNEXT W_Cle FROM W_RESULTAT ELSE W_FINI="VRAI"
	WHILE W_FINI="FAUX" DO
		I=I+1
		ENR_LIENCOMPTA<I>=""
		READ ENR_BROUILLARDDETAIL FROM F.BROUILLARDDETAIL,W_Cle ELSE PRINT "BROUILLARDDETAIL":W_Cle
		W_DateEcriture=OCONV(ENR_BROUILLARDDETAIL<2>, "D4/")
		W_DateEcriture=W_DateEcriture[1,2]:W_DateEcriture[4,2]:W_DateEcriture[9,2]
		ENR_LIENCOMPTA<I>=W_DateEcriture:';99;'

		IF ENR_BROUILLARDDETAIL<6><>"" THEN
			W_Longueur=LEN(ENR_BROUILLARDDETAIL<6>)
			IF W_Longueur<7 THEN
				W_CodePiece=ENR_BROUILLARDDETAIL<6> "R%7"
			END ELSE
				W_CodePiece=ENR_BROUILLARDDETAIL<6>[W_Longueur-6,7]
			END
		END ELSE
			W_CodePiece=""
		END

		ENR_LIENCOMPTA<I>=ENR_LIENCOMPTA<I>:W_CodePiece

		IF LEN(ENR_BROUILLARDDETAIL<4>)=5 THEN
			READ ENR_PARAMENTITECOMPTA FROM F.PARAMENTITECOMPTA,W_Entite ELSE PRINT "PARAMENTITECOMPTA"
			ENR_LIENCOMPTA<I>=ENR_LIENCOMPTA<I>:';':ENR_PARAMENTITECOMPTA<16>[1,9]
			W_CodeAide=ENR_BROUILLARDDETAIL<4> "R(#5)"
			ENR_LIENCOMPTA<I>=ENR_LIENCOMPTA<I>:';':W_CodeAide
		END ELSE
			ENR_LIENCOMPTA<I>=ENR_LIENCOMPTA<I>:';':ENR_BROUILLARDDETAIL<4>[4,9]
			ENR_LIENCOMPTA<I>=ENR_LIENCOMPTA<I>:';'
		END

		ENR_LIENCOMPTA<I>=ENR_LIENCOMPTA<I>:';':ENR_BROUILLARDDETAIL<5>[1,25]

		IF ENR_BROUILLARDDETAIL<7><>"" THEN
			ENR_LIENCOMPTA<I>=ENR_LIENCOMPTA<I>:';D'
			W_Montant=ENR_BROUILLARDDETAIL<7>
			W_Montant=(W_Montant/100) "R2"
			ENR_LIENCOMPTA<I>=ENR_LIENCOMPTA<I>:';':W_Montant
		END ELSE
			ENR_LIENCOMPTA<I>=ENR_LIENCOMPTA<I>:';C'
			W_Montant=ENR_BROUILLARDDETAIL<8>
			W_Montant=(W_Montant/100) "R2"
			ENR_LIENCOMPTA<I>=ENR_LIENCOMPTA<I>:';':W_Montant
		END

		IF ENR_BROUILLARDDETAIL<10><>"" THEN
			W_Quantite=ENR_BROUILLARDDETAIL<10>
			W_Quantite=(W_Quantite/100) "R2"
		END ELSE
			W_Quantite=""
		END

		ENR_LIENCOMPTA<I>=ENR_LIENCOMPTA<I>:';':W_Quantite:';;'

	REPEAT	

RETURN
